.vimrc

   1 " User configuration file for Vi IMproved.
   2 "
   3 " vim 6.0+ required, 7.0+ recommended.
   4
   5 " 1 important
   6
   7 " Remove ALL autocommands in case the file is sourced for the second time
   8 autocmd!
   9
  10 language messages C " Print messages in English
  11
  12 if exists("b:wrap") " Only do this on the second and subsequent :source's
  13    let fenc = &fileencoding
  14    let ftype = &filetype
  15    let mod = &modified
  16    set all& " Reset all options, except terminal options, to their default value.
  17    execute 'set fileencoding=' . fenc
  18    execute 'set filetype=' . ftype
  19    if mod
  20       set modified
  21    else
  22       set nomodified
  23    endif
  24    unlet fenc ftype mod
  25
  26 elseif filereadable($VIMRUNTIME . "/defaults.vim")
  27    unlet! skip_defaults_vim
  28    source $VIMRUNTIME/defaults.vim
  29 endif
  30
  31 " No, it is not VI, it is VIM! It is important to set this first, because this
  32 " command resets many other options.
  33 set nocompatible
  34
  35 " Set behavior to xterm, not mswin
  36 behave xterm
  37
  38 " 2 moving around, searching and patterns
  39
  40 set ignorecase    " Ignore case in search patterns
  41 set noincsearch   " No incremental searching
  42 set smartcase     " Match 'word' case-insensitive and 'Word' case-sensitive
  43
  44 set nostartofline " Keep cursor's column
  45 set whichwrap=b,s,h,l,<,>,[,],~ " Wrap to the previous/next line on all keys and ~ command
  46
  47 " 4 displaying text
  48
  49 set display=lastline,uhex " Show the last line instead of '@'; show non-printable chars as <hex>
  50 set lazyredraw    " Do not update screen while executing macros
  51 set list          " listchars only works with 'list'
  52 " Show tabs, non-breaking/trailing spaces, long lines
  53 set listchars=tab:>_,nbsp:_,trail:_,extends:+,precedes:+
  54 " Another usefull additions: eol:$,space:_
  55 set scrolloff=0 " number of screen lines to show around the cursor
  56 set wrap          " Visually wrap long lines
  57
  58 " With 'set wrap' wrap long lines at a character in 'breakat'
  59 " Please note 'nolist' is required to use 'linebreak'
  60 set linebreak showbreak=+\ " A plus and a space
  61
  62 set sidescroll=1  " The minimal number of columns to scroll horizontally
  63
  64 " 5 highlighting
  65
  66 colorscheme phd
  67 set nohlsearch    " Stop the search highlighting
  68
  69 " 6 multiple windows
  70
  71 set hidden        " Don't unload a buffer when no longer shown in a window; allow to switch between buffers/windows when the buffer is modified
  72 set laststatus=2  " Always show status line
  73
  74 set splitbelow    " A new window is put below of the current one
  75 set splitright    " A new window is put right of the current one
  76
  77 " 8 terminal
  78
  79 set ttyfast       " terminal connection is fast
  80
  81 set title         " Set title to the value of 'titlestring' or to 'filename - VIM'
  82 set titleold=     " string to restore the title to when exiting Vim
  83 " String to use for the Vim window title; with statusline printf items:
  84 " display filename, modification flag, full path, argument list status,
  85 " the current user, host and program name (to distinguish vim/view/etc).
  86 set titlestring=%t%(\ %M%)%(\ (%{expand(\"%:p:h\")})%)%(\ %a%)\ -\ [%{$USER}@%{hostname()}]\ %{v:progname}
  87
  88 " 9 using the mouse
  89
  90 if has('mouse')
  91    set mouse=ar      " Use mouse in all modes, plus hit-return
  92 endif
  93
  94 " 12 messages and info
  95
  96 set ruler         " Show cursor position below each window
  97 set showcmd       " Show (partial) command keys in the status line
  98
  99 " Short message for [Modified];
 100 " overwrite message for writing a file with subsequent message;
 101 " truncate long file messages
 102 set shortmess=mot
 103
 104 " 14 editing text
 105
 106 set backspace=indent,eol,start
 107 set complete+=k   " Scan spell dictionaries for completion in addition to standard places
 108 set infercase     " adjust case of a keyword completion match
 109 set nojoinspaces  " Do not insert two spaces after a '.', '?' and '!' with a join command
 110 set nrformats=hex " I seldom edit octal numbers, but very often dates like 2001-02-01
 111
 112 " Default value 'croql' is a compromise for both natural and programming
 113 " languages, but as any compromise it works good for neither natural nor
 114 " programming languages. This value is good for natural texts,
 115 " let ftplugins to set values suitable for programming languages.
 116 set formatoptions=2t " list of flags that tell how automatic formatting works
 117
 118 " 15 tabs and indenting
 119
 120 set expandtab     " expand <Tab> to spaces in Insert mode
 121 set shiftwidth=3  " number of spaces used for each step of (auto)indent
 122 set smarttab      " a <Tab> in an indent inserts 'shiftwidth' spaces
 123 set softtabstop=3 " number of spaces to insert for a <Tab>
 124
 125 set noautoindent  " Do not automatically set the indent of a new line
 126
 127 " 18 mapping
 128
 129 set timeout timeoutlen=3000 ttimeoutlen=100 " allow timing out up to 3 seconds halfway into a mapping; 100 ms to wait for a key code or mapped key sequence to complete
 130
 131 " 19 reading and writing files
 132 if v:version >= 703
 133    set cryptmethod=blowfish " encryption method for file writing: zip or blowfish
 134 endif
 135
 136 " 20 the swap file
 137
 138 let myUndoDir = expand('~/tmp/vim/undo')
 139 if !isdirectory(myUndoDir)
 140     " Create dirs
 141     call mkdir(myUndoDir, 'p')
 142 endif
 143
 144 " list of directories for the swap file; remove . (the current directory)
 145 if has("win32")
 146    set directory=~/tmp/vim//,$TEMP//,c:/tmp//,c:/temp//
 147 else
 148    set directory=~/tmp/vim//,~/tmp//,/var/tmp//,/tmp//
 149 endif
 150 " if a directory ends in two path separators "//"
 151 " or "\\", the swap file name will be built from the complete path to
 152 " the file with all path separators substituted to percent '%' signs.
 153 " This will ensure file name uniqueness in the preserve directory.
 154
 155 " 21 command line editing
 156
 157 set history=1000  " how many command lines are remembered
 158 set suffixes+=.pyc,.pyo " list of file name extensions that have a lower priority
 159 set wildignore+=*.py[co] " Ignore these patterns when completing file names
 160 set wildmenu      " command-line completion shows a list of matches
 161 set wildmode=longest,list:longest,full " Bash-vim completion behavior
 162
 163 " Keep undo history across sessions by storing it in a file
 164 if has('persistent_undo')
 165     let &undodir = myUndoDir
 166     set undofile
 167 endif
 168
 169 " 22 executing external commands
 170
 171 if has("filterpipe")
 172    set noshelltemp " Use pipes on Unix
 173 endif
 174
 175 " 25 multi-byte characters
 176
 177 " Automatically detected character encodings
 178 set fileencodings=ucs-bom,us-ascii,utf-8,koi8-r,cp1251,cp866,latin1
 179
 180 " 26 various
 181
 182 " ! - when included, save and restore global variables that start
 183 "     with an uppercase letter, and don't contain a lowercase letter;
 184 " h - disable the effect of 'hlsearch';
 185 " ' - number of files for which the marks are remembered;
 186 " " and < - maximum number of lines saved for a register;
 187 " s - maximum size of an item in Kbytes.
 188 set viminfo=!,h,'50
 189 if version < 603
 190    set viminfo+=\"1000
 191 else
 192    set viminfo+=<1000,s10
 193 endif
 194
 195 " c - convert viminfo to the current encoding;
 196 if has("iconv")
 197    set viminfo+=c
 198 endif
 199
 200 " Removable media paths
 201 if has("win32")
 202    set viminfo+=ra:,rb:
 203 endif
 204
 205 " ----------
 206
 207 if has("gui_running")
 208    set background=light
 209
 210    if has("win32")
 211       "set guifont=Courier_New:h18:cRUSSIAN
 212       set guifont=Lucida_Console:h18:cRUSSIAN
 213    else
 214       set guifont=Monospace\ 16
 215       set toolbar=icons,text " how to show the toolbar
 216    endif
 217
 218    set guicursor+=a:blinkon0 " Stop cursor blinking
 219
 220    " Make shift-insert work like in Xterm
 221    " map <S-Insert> <MiddleMouse>
 222    " map! <S-Insert> <MiddleMouse>
 223
 224    " ----------
 225    " From http://slobin.pp.ru/vim/_vimrc.html
 226
 227    " Arrows should go into wrapped lines, but not while popup menu is visible
 228    imap <expr> <Down> pumvisible() ? "<Down>" : "<C-O>gj"
 229    imap <expr> <Up> pumvisible() ? "<Up>" : "<C-O>gk"
 230
 231    " The <CR> key should select from completion menu without adding a newline
 232    imap <expr> <CR> pumvisible() ? "<C-Y>" : "<CR>"
 233    " ----------
 234
 235 else
 236    if (&term =~ "linux") || ($BACKGROUND == 'DARK') || ($BACKGROUND == 'dark')
 237          \ || has("win32")
 238       " Background of the terminal is black or dark grey
 239       set background=dark
 240    else
 241       set background=light
 242    endif
 243
 244    if (&term =~ "linux")
 245       execute 'set t_kb=' . nr2char(127)
 246    endif
 247
 248    if (&term =~ "rxvt") || (&term =~ "screen") || (&term =~ "term") || (&term =~ "vt100")
 249       execute 'set t_kb=' . nr2char(127)
 250
 251       if has ("terminfo")
 252          " set t_Co=256
 253          set t_Co=16
 254       else
 255          set t_Co=8
 256          set t_Sf="\e[3%dm"
 257          set t_Sb="\e[4%dm"
 258       endif
 259
 260       " 'autoselect' to always put selected text on the clipboard;
 261       " 'unnamed' to use the * register like unnamed register '*'
 262       " for all yank, delete and put operations;
 263       " This allows to use mouse for copy/paste in local xterm,
 264       " but prevents to save the unnamed register between sessions.
 265       " set clipboard=autoselect,unnamed,exclude:cons\|linux
 266
 267       " Use xclip to copy/paste to/from X clipboard at remote host
 268       " vmap "+y :!xclip -i -sel clip
 269       " map "+p :r!xclip -o -sel clip
 270       " Enable X11Forwarding and use ssh -X or even -Y
 271    endif
 272
 273    if (&term =~ "screen")
 274       set ttymouse=xterm2 " Enable mouse codes under screen/tmux
 275       if empty(&t_ts)
 276          " Enable window title under screen/tmux
 277          let &t_ts = "\e]2;"
 278          let &t_fs = "\007"
 279       endif
 280    endif
 281
 282    " Bracketed paste mode
 283    " https://github.com/ConradIrwin/vim-bracketed-paste/blob/master/plugin/bracketed-paste.vim
 284    let &t_ti .= "\<Esc>[?2004h"
 285    let &t_te = "\e[?2004l" . &t_te
 286
 287    function! XTermPasteBegin(ret)
 288      set pastetoggle=<f29>
 289      set paste
 290      return a:ret
 291    endfunction
 292
 293    execute "set <f28>=\<Esc>[200~"
 294    execute "set <f29>=\<Esc>[201~"
 295    map <expr> <f28> XTermPasteBegin("i")
 296    imap <expr> <f28> XTermPasteBegin("")
 297    vmap <expr> <f28> XTermPasteBegin("c")
 298    cmap <f28> <nop>
 299    cmap <f29> <nop>
 300
 301    "https://coderwall.com/p/if9mda/automatically-set-paste-mode-in-vim-when-pasting-in-insert-mode
 302    " https://ttssh2.osdn.jp/manual/en/usage/tips/vim.html
 303    function! WrapForScreenTmux(s)
 304       if (&term =~ "screen")
 305          let scr_start = "\<Esc>P"
 306          let scr_end = "\<Esc>\\"
 307
 308          return scr_start . a:s . scr_end
 309       endif
 310
 311       if exists('$TMUX')
 312          let tmux_start = "\<Esc>Ptmux;"
 313          let tmux_end = "\<Esc>\\"
 314
 315          return tmux_start . substitute(a:s, "\<Esc>", "\<Esc>\<Esc>", 'g') . tmux_end
 316       endif
 317
 318       return a:s
 319    endfunction
 320
 321    " https://vim.fandom.com/wiki/Change_cursor_shape_in_different_modes
 322    let &t_EI.=WrapForScreenTmux("\e[2 q") "EI = NORMAL mode (ELSE)
 323    let &t_SI.=WrapForScreenTmux("\e[6 q") "SI = INSERT mode
 324    if v:version >= 800
 325       let &t_SR.=WrapForScreenTmux("\e[4 q") "SR = REPLACE mode
 326    endif
 327
 328    "Cursor settings:
 329    "  1 -> blinking block
 330    "  2 -> solid block
 331    "  3 -> blinking underscore
 332    "  4 -> solid underscore
 333    "  5 -> blinking vertical bar
 334    "  6 -> solid vertical bar
 335 endif
 336
 337 " Multiline comments often confuse vim syntax highlighting - these maps
 338 " allow to resynchronize; the first is faster, the second is more thorough
 339 nmap \sc :syntax sync clear<Enter>
 340 nmap \ss :syntax sync fromstart<Enter>
 341
 342
 343 " AUTOCOMMANDS
 344
 345 " Enable filetype detection
 346 filetype plugin indent on
 347
 348 runtime macros/matchit.vim
 349
 350 " Reread me after editing
 351 autocmd BufWritePost ~/.vimrc source ~/.vimrc | syntax on
 352
 353 if version >= 700
 354 " Save all files before running any quickfix command (grep, makeprg, etc.)
 355 autocmd QuickFixCmdPre * wall
 356 " automatically close quickfix if it's the only window left
 357 autocmd WinEnter * if winnr('$') == 1 &&
 358    \ index(["nofile", "quickfix"], &buftype) >= 0 | quit | endif
 359 endif
 360
 361 " Syntax highlighting
 362 autocmd BufReadPost * syntax on
 363
 364
 365 " Restore last known cursor position
 366 function! RestorePosition()
 367    if exists('b:position_restored')
 368       return
 369    endif
 370
 371    if line("'\"") > 0
 372       call cursor(line("'\""), col("'\""))
 373    endif
 374    let b:position_restored = 1
 375 endfunction
 376
 377 " When editing a file, always jump to the last cursor position (if saved)
 378 autocmd BufReadPost * call RestorePosition()
 379
 380
 381 function! SetupEncoding(encoding)
 382    if !has("iconv") || exists('b:encoding_set') || strlen(a:encoding) == 0
 383       return
 384    endif
 385
 386    call RestorePosition()
 387    let b:encoding_set = 1
 388    if len(expand('%'))
 389       execute "edit ++enc=" . a:encoding
 390    endif
 391 endfunction
 392
 393
 394 " From http://lwn.net/Articles/226514/
 395
 396 augroup gpg
 397 " Remove ALL autocommands for the current group.
 398 autocmd!
 399 autocmd BufReadPre,FileReadPre *.gpg set viminfo=
 400 autocmd BufReadPre,FileReadPre *.gpg setlocal noswapfile
 401 autocmd BufReadPost *.gpg :%!gpg -q -d
 402 autocmd BufReadPost *.gpg | redraw
 403 autocmd BufWritePre *.gpg :%!gpg --default-recipient-self -q -e -a
 404 autocmd BufWritePost *.gpg u
 405 autocmd VimLeave *.gpg :!clear
 406 " For OpenSSL:
 407 " BufReadPost: use "openssl bf -d -a"
 408 " BufWritePre: use "openssl bf -salt -a"
 409 augroup END
 410
 411
 412 function! SetWrap()
 413    setlocal wrap
 414    map <Up> gk
 415    imap <Up> <C-O>gk
 416    map <Down> gj
 417    imap <Down> <C-O>gj
 418    let b:wrap = 1
 419 endfunction
 420
 421 function! SetNoWrap()
 422    setlocal nowrap
 423    map <Up> k
 424    map <Down> j
 425    let b:wrap = 0
 426 endfunction
 427
 428 command! SetWrap call SetWrap()
 429 command! SetNoWrap call SetNoWrap()
 430
 431 " b:wrap can be set by an ftplugin
 432 autocmd BufReadPost * if !exists("b:wrap") | call SetWrap() | endif
 433
 434
 435 " MAPPINGS
 436
 437 " Do not unindent #-comment
 438 inoremap # X<C-H>#
 439
 440 " map <C-A> <Home>
 441 " map <C-E> <End>
 442 " map <C-Z> :shell<CR>
 443
 444
 445 if version >= 700
 446 " WEB BROWSERS
 447
 448 let s:URL_re="\\v(((https?|ftp|gopher|telnet)://|(mailto|file|news|about|ed2k|irc|sip|magnet):)[^' \t<>\"]+|(www|web|w3)[a-z0-9_-]*\\.[a-z0-9._-]+\\.[^' \t<>\"]+)[a-z0-9/]\\c"
 449
 450 function! ExtractURL()
 451    let line = getline('.')
 452    let parts = split(line, s:URL_re . '\zs')
 453
 454    if len(parts) == 0
 455       throw 'ExtractURLCannotFindURL' " No URL found
 456    endif
 457
 458    let length = 0
 459    let column = col('.')
 460
 461    for p in parts
 462       let save_length = length
 463       let length += len(p)
 464       if length >= column
 465          break
 466       endif
 467    endfor
 468
 469    let pos = match(p, s:URL_re)
 470    if pos == -1
 471       throw 'ExtractURLCannotFindURL' " No URL found
 472    endif
 473
 474    if save_length + pos >= column " cursor left of the URL
 475       throw 'ExtractURLCannotFindURL'
 476    endif
 477
 478    return strpart(p, pos)
 479 endfunction
 480
 481 function! EscapeURL(url)
 482    let url = substitute(a:url, ' ', '%20', 'g')
 483    return escape(url, '!#$%')
 484 endfunction
 485
 486 function! OpenURL(url, newwin)
 487    execute "!webbrowser " . a:newwin . " '" . EscapeURL(a:url) . "'"
 488 endfunction
 489
 490 function! ExtractOpenURL(newwin)
 491    try
 492       let url = ExtractURL()
 493    catch /^ExtractURLCannotFindURL$/
 494       echoerr 'No URL found under cursor'
 495       return
 496    endtry
 497
 498    call OpenURL(url, a:newwin)
 499 endfunction
 500
 501 function! EncodeOpenURL(url, newwin)
 502    execute "!webbrowser-encode-url " . a:newwin . " '" . EscapeURL(a:url) . "'"
 503 endfunction
 504
 505
 506 " Send current link to a browser
 507 nmap \b :call ExtractOpenURL('')<CR>
 508 nmap \w :call ExtractOpenURL('-n')<CR>
 509 nmap \t :call ExtractOpenURL('-t')<CR>
 510 " Send visual block to a browser
 511 vmap \b ""y:call OpenURL('<C-R>"', '')<CR>
 512 vmap \w ""y:call OpenURL('<C-R>"', '-n')<CR>
 513 vmap \t ""y:call OpenURL('<C-R>"', '-t')<CR>
 514 " Encode and send visual block to a browser
 515 vmap \B ""y:call EncodeOpenURL('<C-R>"', '')<CR>
 516 vmap \W ""y:call EncodeOpenURL('<C-R>"', '-n')<CR>
 517 vmap \T ""y:call EncodeOpenURL('<C-R>"', '-t')<CR>
 518 " Send current file's name to a browser
 519 nmap \B :call EncodeOpenURL('file:' . expand("%:p"), '')<CR>
 520 nmap \W :call EncodeOpenURL('file:' . expand("%:p"), '-n')<CR>
 521 nmap \T :call EncodeOpenURL('file:' . expand("%:p"), '-t')<CR>
 522
 523 endif " version >= 700
 524
 525
 526 " SPELLING
 527
 528 if has("spell") " Works in 7.0+
 529    " Use builtin spellchecker
 530    nmap \sv :syntax off <BAR> setlocal spell<CR>
 531    " Clear
 532    nmap \sn :syntax on <BAR> setlocal nospell<CR>
 533 endif
 534
 535
 536 " Russian letters mapped in normal mode
 537 "if has("keymap")
 538 "   set keymap=russian-jcuken
 539 "endif
 540
 541 if has("langmap")
 542    if v:version >= 702
 543       " langmap in utf-8 mode requires at least Vim 7.2.109
 544       scriptencoding utf-8
 545       set langmap=ё`Ё~йqцwуeкrеtнyгuшiщoзpх[ъ]фaыsвdаfпgрhоjлkдlж\\;э'
 546                  \яzчxсcмvиbтnьmб\\,ю.ЙQЦWУEКRЕTНYГUШIЩOЗPХ{Ъ}
 547                  \ФAЫSВDАFПGРHОJЛKДLЖ:Э\\"ЯZЧXСCМVИBТNЬMБ<Ю>
 548
 549    elseif &encoding != 'utf-8'
 550       scriptencoding koi8-r
 551       set langmap=ё`Ё~йqцwуeкrеtнyгuшiщoзpх[ъ]фaыsвdаfпgрhоjлkдlж\\;э'
 552                  \яzчxсcмvиbтnьmб\\,ю.ЙQЦWУEКRЕTНYГUШIЩOЗPХ{Ъ}
 553                  \ФAЫSВDАFПGРHОJЛKДLЖ:Э\\"ЯZЧXСCМVИBТNЬMБ<Ю>
 554    endif
 555
 556    scriptencoding us-ascii
 557 endif
 558
 559
 560 if version >= 700
 561 function! W()
 562    " let encodings=filter(split(&fileencodings, ','), 'v:val != "ucs-bom"')
 563    let encodings = ['us-ascii']
 564    if $LC_CTYPE =~ 'UTF-8' " UTF-8 or en_US.UTF-8 or ru_RU.UTF-8 or such
 565       let encodings += ['utf-8']
 566    elseif $LC_CTYPE == 'ru_RU.KOI8-R'
 567       let encodings += ['koi8-r', 'utf-8']
 568    elseif v:lc_time == 'Russian_Russia.1251'
 569       let encodings += ['cp1251', 'utf-8']
 570    endif
 571
 572    for e in encodings
 573       try
 574          execute 'set fileencoding=' . e
 575          w
 576          break
 577       catch /E513: write error, conversion failed/
 578          continue
 579       endtry
 580    endfor
 581
 582    if &modified
 583       throw '"' . expand('%') . '" E513: write error, conversion failed; tried ' . join(encodings, ',')
 584    elseif has("spell")
 585       call SetupSpell()
 586    endif
 587 endfunction
 588
 589 command! W call W()
 590 endif
 591
 592
 593 function! SlowTerm()
 594    set laststatus=1
 595    set noruler
 596    set shortmess=aoOtT
 597    set noshowcmd
 598    set scrolljump=5 " The minimal number of lines to scroll vertically when the cursor gets of the screen
 599    set sidescroll=5
 600    set nottyfast
 601    set notitle
 602    set timeoutlen=5000
 603    set nowildmenu
 604    set wildmode=list:longest
 605    set viminfo=!,h,'10,<100,s5
 606    if has("iconv")
 607       set viminfo+=c
 608    endif
 609    syntax off
 610    highlight NonText cterm=NONE ctermfg=NONE
 611 endfunction
 612
 613 if exists("$SLOWTERM")
 614    call SlowTerm()
 615 endif
 616
 617
 618 if has("python")
 619 pyfile ~/.vim/python/virtualenv.py
 620 endif
 621
 622 if has("python3")
 623 py3file ~/.vim/python/virtualenv.py
 624 endif
 625
 626
 627 " From Tip 212:
 628 " http://vim.fandom.com/wiki/Setting_file_attributes_without_reloading_a_buffer
 629
 630 if executable('chmod')
 631    function! SetExecutableBit(x)
 632       checktime
 633       " Avoid 'Reload Y/N?' question
 634       autocmd FileChangedShell <buffer> call _BufChangedCB()
 635       let fx = executable(expand("%:p"))
 636       if a:x && !fx
 637          silent !chmod a+x %
 638       elseif !a:x && fx
 639          silent !chmod a-x %
 640       endif
 641       if v:shell_error
 642          echoerr 'Error running chmod: ' . v:shell_error
 643       endif
 644       checktime
 645       autocmd! FileChangedShell <buffer>
 646    endfunction
 647    function! _BufChangedCB()
 648       autocmd! FileChangedShell <buffer>
 649    endfunction
 650    command! ToggleXbit if executable(expand("%:p")) | call SetExecutableBit(0) | else | call SetExecutableBit(1) | endif
 651 endif
 652
 653 function! Code()
 654     setlocal expandtab tabstop=8 softtabstop=4 shiftwidth=4
 655 endfunction
 656 command! Code call Code()
 657
 658 function! Text()
 659     setlocal expandtab tabstop=8 softtabstop=3 shiftwidth=3
 660 endfunction
 661 command! Text call Text()
 662
 663 " ----------
 664 " From http://slobin.pp.ru/vim/_vimrc.html
 665
 666 " These options will be kept between editing sessions
 667 " let options = []
 668
 669 " Called automagically after .viminfo and plugins are loaded, sets
 670 " miscellaneous options from persistent global variables
 671 " function! VimEnter()
 672   " for optname in g:options
 673   "   let varname = "g:OPT_" . toupper(optname)
 674   "   if exists(varname)
 675   "     execute "let &" . optname . " = " . varname
 676   "   endif
 677   " endfor
 678
 679   " if has("gui_running") && exists("g:WINPOSX") && exists("g:WINPOSY")
 680   "   execute "winpos" g:WINPOSX g:WINPOSY
 681   " endif
 682 " endfunction
 683
 684 " Called automagically before .viminfo is saved, saves miscellaneous
 685 " options into persistent global variables
 686 " function! VimLeavePre()
 687   " call filter(g:, 'v:key !~# "^OPT_"')
 688   " for optname in g:options
 689   "   let varname = "g:OPT_" . toupper(optname)
 690   "   execute "let " . varname . " = &g:" . optname
 691   " endfor
 692
 693   " if has("gui_running")
 694   "   let g:WINPOSX = getwinposx()
 695   "   let g:WINPOSY = getwinposy()
 696   " endif
 697 " endfunction
 698
 699 " autocmd VimEnter * call VimEnter()
 700 " autocmd VimLeavePre * call VimLeavePre()
 701
 702
 703 " Called automagically after every buffer read, enables fileencoding
 704 " setting from modeline (see Tip #911:
 705 " http://vim.fandom.com/wiki/How_to_make_fileencoding_work_in_the_modeline)
 706 function! AutoEncoding()
 707   if &modified && &fileencoding != ""
 708     call SetupEncoding(&fileencoding)
 709   else
 710     redraw
 711   endif
 712   autocmd! auto-encoding
 713   augroup! auto-encoding
 714 endfunction
 715
 716 augroup auto-encoding
 717 autocmd!
 718 autocmd BufWinEnter * call AutoEncoding()
 719 augroup END
 720
 721
 722 let CONVERT=1
 723
 724 " Value of a character under cursor; better than standard '0x%02B (%b)'
 725 function! HexDec()
 726   let char = matchstr(getline("."), ".", col(".") - 1)
 727   if g:CONVERT
 728     let char = iconv(char, &encoding, &fileencoding)
 729     let format = "0x%02X <%d>"
 730   else
 731     let format = "0x%02X (%d)"
 732   endif
 733   let char = char2nr(char)
 734   return printf(format, char, char)
 735 endfunction
 736
 737
 738 if has("iconv")
 739    " Helper function for :DecodeQP and :DecodeURL commands
 740    function! DecodeHex(arg)
 741      return iconv(printf("%c", str2nr(submatch(1), 16)), a:arg, &encoding)
 742    endfunction
 743
 744    " Custom completion for encoding names
 745    function! EncList(ArgLead, CmdLine, CursorPos)
 746      return filter(split(&fileencodings, ','),
 747                  \ "strpart(v:val, 0, strlen(a:ArgLead)) == a:ArgLead")
 748    endfunction
 749
 750    if version >= 700
 751    " Command for decoding qp-encoded text
 752    command! -bar -nargs=? -range -complete=customlist,EncList DecodeQP
 753           \ <line1>,<line2>s/=\(\x\x\|\n\)/\=DecodeHex(<q-args>)/eg
 754
 755    " Command for decoding url-encoded text
 756    command! -bar -nargs=? -range -complete=customlist,EncList DecodeURL
 757           \ <line1>,<line2>s/%\(\x\x\)/\=DecodeHex(<q-args>)/eg
 758    endif
 759 endif
 760
 761
 762 if has("spell")
 763    function! SetupSpell()
 764       if &fileencoding =~ 'ascii'
 765          setlocal spelllang=en spellfile=~/.vim/spell/en.ascii.add
 766       elseif &fileencoding == 'koi8-r'
 767          setlocal spelllang=en,ru spellfile=~/.vim/spell/en.ascii.add,~/.vim/spell/ru.koi8-r.add
 768       elseif &fileencoding == 'utf-8'
 769          setlocal spelllang=en,ru spellfile=~/.vim/spell/en.ascii.add,~/.vim/spell/ru.utf-8.add
 770       else
 771          setlocal spelllang= spellfile=
 772       endif
 773    endfunction
 774    autocmd BufReadPost * call SetupSpell()
 775
 776    function! SaveSpell()
 777       if expand('%') == expand('~/.vim/spell/en.ascii.add')
 778          mkspell! -ascii %
 779       else
 780          mkspell! %
 781       endif
 782    endfunction
 783    autocmd BufWritePost ~/.vim/spell/*.add call SaveSpell()
 784 endif
 785
 786
 787 function! SyntaxName()
 788   echomsg synIDattr(synID(line("."), col("."), 1), "name")
 789 endfunction
 790
 791
 792 if has("python")
 793 pyfile ~/.vim/python/completion.py
 794
 795 " Custom completion for python expressions
 796 function! CompList(ArgLead, CmdLine, CursorPos)
 797   python vim_comp_list()
 798 endfunction
 799
 800 " Python command line calculator
 801 command! -nargs=+ -range -complete=customlist,CompList Calc
 802        \ <line1>,<line2> python vim_calc(<q-args>)
 803
 804 " Python text range filter
 805 command! -nargs=+ -range -complete=customlist,CompList Pydo
 806        \ <line1>,<line2> python vim_pydo(<q-args>)
 807
 808 " Display unicode name for the character under cursor
 809 command! Uname python vim_unicode_name()
 810 endif
 811
 812 if has("python3")
 813 py3file ~/.vim/python/completion.py
 814
 815 " Custom completion for python expressions
 816 function! CompList(ArgLead, CmdLine, CursorPos)
 817   python3 vim_comp_list()
 818 endfunction
 819
 820 " Python command line calculator
 821 command! -nargs=+ -range -complete=customlist,CompList Calc
 822        \ <line1>,<line2> python3 vim_calc(<q-args>)
 823
 824 " Python text range filter
 825 command! -nargs=+ -range -complete=customlist,CompList Pydo
 826        \ <line1>,<line2> python3 vim_pydo(<q-args>)
 827
 828 " Display unicode name for the character under cursor
 829 command! Uname python3 vim_unicode_name()
 830 endif
 831
 832 if has("python") || has("python3")
 833 command! UName Uname
 834 endif
 835 " ----------
 836
 837 " This has to go to the very end of ~/.vimrc to allow reading the .vimrc
 838 set secure        " safer working with script files in the current directory