.vimrc

   1 " User configuration file for Vi IMproved.
   2 "
   3 " vim 6.0+ required, 7.0+ recommended.
   4
   5 " 1 important
   6
   7 " Remove ALL autocommands in case the file is sourced for the second time
   8 autocmd!
   9
  10 language messages C " Print messages in English
  11
  12 if exists("b:wrap") " Only do this on the second and subsequent :source's
  13    let fenc = &fileencoding
  14    let ftype = &filetype
  15    let mod = &modified
  16    set all& " Reset all options, except terminal options, to their default value.
  17    execute 'set fileencoding=' . fenc
  18    execute 'set filetype=' . ftype
  19    if mod
  20       set modified
  21    else
  22       set nomodified
  23    endif
  24    unlet fenc ftype mod
  25
  26 elseif filereadable($VIMRUNTIME . "/defaults.vim")
  27    unlet! skip_defaults_vim
  28    source $VIMRUNTIME/defaults.vim
  29 endif
  30
  31 " No, it is not VI, it is VIM! It is important to set this first, because this
  32 " command resets many other options.
  33 set nocompatible
  34
  35 " Set behavior to xterm, not mswin
  36 behave xterm
  37
  38 " 2 moving around, searching and patterns
  39
  40 set ignorecase    " Ignore case in search patterns
  41 set noincsearch   " No incremental searching
  42 set smartcase     " Match 'word' case-insensitive and 'Word' case-sensitive
  43
  44 set nostartofline " Keep cursor's column
  45 set whichwrap=b,s,h,l,<,>,[,],~ " Wrap to the previous/next line on all keys and ~ command
  46
  47 " 4 displaying text
  48
  49 set display=lastline,uhex " Show the last line instead of '@'; show non-printable chars as <hex>
  50
  51 " Do not set it here, it breaks initial screen drawing and cursor positioning.
  52 " See SetLazyRedraw at the end of the script.
  53 " set lazyredraw  " Do not update screen while executing macros
  54
  55 set list          " listchars only works with 'list'
  56 " Show tabs, non-breaking/trailing spaces, long lines
  57 set listchars=tab:>_,nbsp:_,trail:_,extends:+,precedes:+
  58 " Another usefull additions: eol:$,space:_
  59 set scrolloff=0 " number of screen lines to show around the cursor
  60 set wrap          " Visually wrap long lines
  61
  62 " With 'set wrap' wrap long lines at a character in 'breakat'
  63 " Please note 'nolist' is required to use 'linebreak'
  64 set linebreak showbreak=+\ " A plus and a space
  65
  66 set sidescroll=1  " The minimal number of columns to scroll horizontally
  67
  68 " 5 highlighting
  69
  70 colorscheme phd
  71 set nohlsearch    " Stop the search highlighting
  72
  73 " 6 multiple windows
  74
  75 set hidden        " Don't unload a buffer when no longer shown in a window; allow to switch between buffers/windows when the buffer is modified
  76 set laststatus=2  " Always show status line
  77
  78 set splitbelow    " A new window is put below of the current one
  79 set splitright    " A new window is put right of the current one
  80
  81 " 8 terminal
  82
  83 set ttyfast       " terminal connection is fast
  84
  85 set title         " Set title to the value of 'titlestring' or to 'filename - VIM'
  86 set titleold=     " string to restore the title to when exiting Vim
  87 " String to use for the Vim window title; with statusline printf items:
  88 " display filename, modification flag, full path, argument list status,
  89 " the current user, host and program name (to distinguish vim/view/etc).
  90 set titlestring=%t%(\ %M%)%(\ (%{expand(\"%:p:h\")})%)%(\ %a%)\ -\ [%{$USER}@%{hostname()}]\ %{v:progname}
  91
  92 " 9 using the mouse
  93
  94 if has('mouse')
  95    set mouse=ar      " Use mouse in all modes, plus hit-return
  96 endif
  97
  98 " 12 messages and info
  99
 100 set ruler         " Show cursor position below each window
 101 set showcmd       " Show (partial) command keys in the status line
 102 set visualbell    " Use visual bell instead of beeping
 103 if v:version >= 800
 104    set belloff=error,insertmode " Do not ring the bell for these reasons
 105 endif
 106
 107 " Short message for [Modified];
 108 " overwrite message for writing a file with subsequent message;
 109 " truncate long file messages
 110 set shortmess=mot
 111
 112 " 14 editing text
 113
 114 set backspace=indent,eol,start
 115 set complete+=k   " Scan spell dictionaries for completion in addition to standard places
 116 set infercase     " adjust case of a keyword completion match
 117 set nojoinspaces  " Do not insert two spaces after a '.', '?' and '!' with a join command
 118 set nrformats=hex " I seldom edit octal numbers, but very often dates like 2001-02-01
 119
 120 " Default value 'croql' is a compromise for both natural and programming
 121 " languages, but as any compromise it works good for neither natural nor
 122 " programming languages. This value is good for natural texts,
 123 " let ftplugins to set values suitable for programming languages.
 124 set formatoptions=2t " list of flags that tell how automatic formatting works
 125
 126 " 15 tabs and indenting
 127
 128 set expandtab     " expand <Tab> to spaces in Insert mode
 129 set shiftwidth=3  " number of spaces used for each step of (auto)indent
 130 set smarttab      " a <Tab> in an indent inserts 'shiftwidth' spaces
 131 set softtabstop=3 " number of spaces to insert for a <Tab>
 132
 133 set noautoindent  " Do not automatically set the indent of a new line
 134
 135 " 18 mapping
 136
 137 set timeout timeoutlen=3000 ttimeoutlen=100 " allow timing out up to 3 seconds halfway into a mapping; 100 ms to wait for a key code or mapped key sequence to complete
 138
 139 " 19 reading and writing files
 140 if v:version >= 703
 141    set cryptmethod=blowfish " encryption method for file writing: zip or blowfish
 142 endif
 143
 144 " 20 the swap file
 145
 146 let myUndoDir = expand('~/tmp/vim/undo')
 147 if !isdirectory(myUndoDir)
 148     " Create dirs
 149     call mkdir(myUndoDir, 'p')
 150 endif
 151
 152 " list of directories for the swap file; remove . (the current directory)
 153 if has("win32")
 154    set directory=~/tmp/vim//,$TEMP//,c:/tmp//,c:/temp//
 155 else
 156    set directory=~/tmp/vim//,~/tmp//,/var/tmp//,/tmp//
 157 endif
 158 " if a directory ends in two path separators "//"
 159 " or "\\", the swap file name will be built from the complete path to
 160 " the file with all path separators substituted to percent '%' signs.
 161 " This will ensure file name uniqueness in the preserve directory.
 162
 163 " 21 command line editing
 164
 165 set history=1000  " how many command lines are remembered
 166 set suffixes+=.pyc,.pyo " list of file name extensions that have a lower priority
 167 set wildignore+=*.py[co] " Ignore these patterns when completing file names
 168 set wildmenu      " command-line completion shows a list of matches
 169 set wildmode=longest,list:longest,full " Bash-vim completion behavior
 170
 171 " Keep undo history across sessions by storing it in a file
 172 if has('persistent_undo')
 173     let &undodir = myUndoDir
 174     set undofile
 175 endif
 176
 177 " 22 executing external commands
 178
 179 if has("filterpipe")
 180    set noshelltemp " Use pipes on Unix
 181 endif
 182
 183 " 25 multi-byte characters
 184
 185 " Automatically detected character encodings
 186 set fileencodings=ucs-bom,us-ascii,utf-8,koi8-r,cp1251,cp866,latin1
 187
 188 " 26 various
 189
 190 " ! - when included, save and restore global variables that start
 191 "     with an uppercase letter, and don't contain a lowercase letter;
 192 " h - disable the effect of 'hlsearch';
 193 " ' - number of files for which the marks are remembered;
 194 " " and < - maximum number of lines saved for a register;
 195 " s - maximum size of an item in Kbytes.
 196 set viminfo=!,h,'50
 197 if version < 603
 198    set viminfo+=\"1000
 199 else
 200    set viminfo+=<1000,s10
 201 endif
 202
 203 " c - convert viminfo to the current encoding;
 204 if has("iconv")
 205    set viminfo+=c
 206 endif
 207
 208 " Removable media paths
 209 if has("win32")
 210    set viminfo+=ra:,rb:
 211 endif
 212
 213 " ----------
 214
 215 if has("gui_running")
 216    set background=light
 217
 218    if has("win32")
 219       "set guifont=Courier_New:h18:cRUSSIAN
 220       set guifont=Lucida_Console:h18:cRUSSIAN
 221    else
 222       set guifont=Monospace\ 16
 223       set toolbar=icons,text " how to show the toolbar
 224    endif
 225
 226    set guicursor+=n:block " Block cursor in normal mode
 227    set guicursor+=i:ver10 " Solid vertical bar in insert mode
 228    set guicursor+=a:blinkon0 " Stop cursor blinking
 229
 230    " Make shift-insert work like in Xterm
 231    " map <S-Insert> <MiddleMouse>
 232    " map! <S-Insert> <MiddleMouse>
 233
 234    " ----------
 235    " From http://slobin.pp.ru/vim/_vimrc.html
 236
 237    " Arrows should go into wrapped lines, but not while popup menu is visible
 238    imap <expr> <Down> pumvisible() ? "<Down>" : "<C-O>gj"
 239    imap <expr> <Up> pumvisible() ? "<Up>" : "<C-O>gk"
 240
 241    " The <CR> key should select from completion menu without adding a newline
 242    imap <expr> <CR> pumvisible() ? "<C-Y>" : "<CR>"
 243    " ----------
 244
 245 else
 246    if (&term =~ "linux") || (&term =~ "cygwin") || (&term =~ "putty")
 247          \ || ($BACKGROUND == 'DARK') || ($BACKGROUND == 'dark')
 248          \ || has("win32")
 249       " Background of the terminal is black or dark grey
 250       set background=dark
 251    else
 252       set background=light
 253    endif
 254
 255    if (&term =~ "linux")
 256       execute 'set t_kb=' . nr2char(127)
 257    endif
 258
 259    if (&term =~ "rxvt") || (&term =~ "screen") || (&term =~ "term") || (&term =~ "vt100")
 260       execute 'set t_kb=' . nr2char(127)
 261
 262       if has ("terminfo")
 263          " set t_Co=256
 264          set t_Co=16
 265       else
 266          set t_Co=8
 267          set t_Sf="\e[3%dm"
 268          set t_Sb="\e[4%dm"
 269       endif
 270
 271       " 'autoselect' to always put selected text on the clipboard;
 272       " 'unnamed' to use the * register like unnamed register '*'
 273       " for all yank, delete and put operations;
 274       " This allows to use mouse for copy/paste in local xterm,
 275       " but prevents to save the unnamed register between sessions.
 276       " set clipboard=autoselect,unnamed,exclude:cons\|linux
 277
 278       " Use xclip to copy/paste to/from X clipboard at remote host
 279       " vmap "+y :!xclip -i -sel clip
 280       " map "+p :r!xclip -o -sel clip
 281       " Enable X11Forwarding and use ssh -X or even -Y
 282    endif
 283
 284    if (&term =~ "screen")
 285       set ttymouse=xterm2 " Enable mouse codes under screen/tmux
 286       if empty(&t_ts)
 287          " Enable window title under screen/tmux
 288          let &t_ts = "\e]2;"
 289          let &t_fs = "\007"
 290       endif
 291    endif
 292
 293    " Bracketed paste mode
 294    " https://github.com/ConradIrwin/vim-bracketed-paste/blob/master/plugin/bracketed-paste.vim
 295    let &t_ti .= "\<Esc>[?2004h"
 296    let &t_te = "\e[?2004l" . &t_te
 297
 298    function! XTermPasteBegin(ret)
 299      set pastetoggle=<f29>
 300      set paste
 301      return a:ret
 302    endfunction
 303
 304    execute "set <f28>=\<Esc>[200~"
 305    execute "set <f29>=\<Esc>[201~"
 306    map <expr> <f28> XTermPasteBegin("i")
 307    imap <expr> <f28> XTermPasteBegin("")
 308    vmap <expr> <f28> XTermPasteBegin("c")
 309    cmap <f28> <nop>
 310    cmap <f29> <nop>
 311
 312    "https://coderwall.com/p/if9mda/automatically-set-paste-mode-in-vim-when-pasting-in-insert-mode
 313    " https://ttssh2.osdn.jp/manual/en/usage/tips/vim.html
 314    function! WrapForScreenTmux(s)
 315       if (&term =~ "screen")
 316          let scr_start = "\<Esc>P"
 317          let scr_end = "\<Esc>\\"
 318
 319          return scr_start . a:s . scr_end
 320       endif
 321
 322       if exists('$TMUX')
 323          let tmux_start = "\<Esc>Ptmux;"
 324          let tmux_end = "\<Esc>\\"
 325
 326          return tmux_start . substitute(a:s, "\<Esc>", "\<Esc>\<Esc>", 'g') . tmux_end
 327       endif
 328
 329       return a:s
 330    endfunction
 331
 332    " https://vim.fandom.com/wiki/Change_cursor_shape_in_different_modes
 333    let &t_EI.=WrapForScreenTmux("\e[2 q") "EI = NORMAL mode (ELSE)
 334    let &t_SI.=WrapForScreenTmux("\e[6 q") "SI = INSERT mode
 335    if v:version >= 800
 336       let &t_SR.=WrapForScreenTmux("\e[4 q") "SR = REPLACE mode
 337    endif
 338
 339    "Cursor settings:
 340    "  1 -> blinking block
 341    "  2 -> solid block
 342    "  3 -> blinking underscore
 343    "  4 -> solid underscore
 344    "  5 -> blinking vertical bar
 345    "  6 -> solid vertical bar
 346 endif
 347
 348 " Multiline comments often confuse vim syntax highlighting - these maps
 349 " allow to resynchronize; the first is faster, the second is more thorough
 350 nmap \sc :syntax sync clear<Enter>
 351 nmap \ss :syntax sync fromstart<Enter>
 352
 353
 354 " AUTOCOMMANDS
 355
 356 " Enable filetype detection
 357 filetype plugin indent on
 358
 359 runtime macros/matchit.vim
 360
 361 " Reread me after editing
 362 autocmd BufWritePost ~/.vimrc source ~/.vimrc | syntax on
 363
 364 if version >= 700
 365 " Save all files before running any quickfix command (grep, makeprg, etc.)
 366 autocmd QuickFixCmdPre * wall
 367 " automatically close quickfix if it's the only window left
 368 autocmd WinEnter * if winnr('$') == 1 &&
 369    \ index(["nofile", "quickfix"], &buftype) >= 0 | quit | endif
 370 endif
 371
 372 " Syntax highlighting
 373 autocmd BufReadPost * syntax on
 374
 375
 376 " Restore last known cursor position
 377 function! RestorePosition()
 378    if exists('b:position_restored')
 379       return
 380    endif
 381
 382    if line("'\"") > 0
 383       call cursor(line("'\""), col("'\""))
 384    endif
 385    let b:position_restored = 1
 386 endfunction
 387
 388 " When editing a file, always jump to the last cursor position (if saved)
 389 autocmd BufReadPost * call RestorePosition()
 390
 391
 392 function! SetupEncoding(encoding)
 393    if !has("iconv") || exists('b:encoding_set') || empty(a:encoding)
 394       return
 395    endif
 396
 397    call RestorePosition()
 398    let b:encoding_set = 1
 399    if !empty(expand('%'))
 400       execute "edit ++enc=" . a:encoding
 401    endif
 402 endfunction
 403
 404
 405 " From http://lwn.net/Articles/226514/
 406
 407 augroup gpg
 408 " Remove ALL autocommands for the current group.
 409 autocmd!
 410 autocmd BufReadPre,FileReadPre *.gpg set viminfo=
 411 autocmd BufReadPre,FileReadPre *.gpg setlocal noswapfile
 412 autocmd BufReadPost *.gpg :%!gpg -q -d
 413 autocmd BufReadPost *.gpg | redraw
 414 autocmd BufWritePre *.gpg :%!gpg --default-recipient-self -q -e -a
 415 autocmd BufWritePost *.gpg u
 416 autocmd VimLeave *.gpg :!clear
 417 " For OpenSSL:
 418 " BufReadPost: use "openssl bf -d -a"
 419 " BufWritePre: use "openssl bf -salt -a"
 420 augroup END
 421
 422
 423 function! SetWrap()
 424    setlocal wrap
 425    map <Up> gk
 426    imap <Up> <C-O>gk
 427    map <Down> gj
 428    imap <Down> <C-O>gj
 429    let b:wrap = 1
 430 endfunction
 431
 432 function! SetNoWrap()
 433    setlocal nowrap
 434    map <Up> k
 435    map <Down> j
 436    let b:wrap = 0
 437 endfunction
 438
 439 command! SetWrap call SetWrap()
 440 command! SetNoWrap call SetNoWrap()
 441
 442 " b:wrap can be set by an ftplugin
 443 autocmd BufReadPost * if !exists("b:wrap") | call SetWrap() | endif
 444
 445
 446 " MAPPINGS
 447
 448 " Do not unindent #-comment
 449 inoremap # X<C-H>#
 450
 451 " map <C-A> <Home>
 452 " map <C-E> <End>
 453 " map <C-Z> :shell<CR>
 454
 455
 456 if version >= 700
 457 " WEB BROWSERS
 458
 459 let s:URL_re="\\v(((https?|ftp|gopher|telnet)://|(mailto|file|news|about|ed2k|irc|sip|magnet):)[^' \t<>\"]+|(www|web|w3)[a-z0-9_-]*\\.[a-z0-9._-]+\\.[^' \t<>\"]+)[a-z0-9/]\\c"
 460
 461 function! ExtractURL()
 462    let line = getline('.')
 463    let parts = split(line, s:URL_re . '\zs')
 464
 465    if empty(parts)
 466       throw 'ExtractURLCannotFindURL' " No URL found
 467    endif
 468
 469    let length = 0
 470    let column = col('.')
 471
 472    for p in parts
 473       let save_length = length
 474       let length += len(p)
 475       if length >= column
 476          break
 477       endif
 478    endfor
 479
 480    let pos = match(p, s:URL_re)
 481    if pos == -1
 482       throw 'ExtractURLCannotFindURL' " No URL found
 483    endif
 484
 485    if save_length + pos >= column " cursor left of the URL
 486       throw 'ExtractURLCannotFindURL'
 487    endif
 488
 489    return strpart(p, pos)
 490 endfunction
 491
 492 function! EscapeURL(url)
 493    let url = substitute(a:url, ' ', '%20', 'g')
 494    return escape(url, '!#$%')
 495 endfunction
 496
 497 function! OpenURL(url, newwin)
 498    execute "!webbrowser " . a:newwin . " '" . EscapeURL(a:url) . "'"
 499 endfunction
 500
 501 function! ExtractOpenURL(newwin)
 502    try
 503       let url = ExtractURL()
 504    catch /^ExtractURLCannotFindURL$/
 505       echoerr 'No URL found under cursor'
 506       return
 507    endtry
 508
 509    call OpenURL(url, a:newwin)
 510 endfunction
 511
 512 function! EncodeOpenURL(url, newwin)
 513    execute "!webbrowser-encode-url " . a:newwin . " '" . EscapeURL(a:url) . "'"
 514 endfunction
 515
 516
 517 " Send current link to a browser
 518 nmap \b :call ExtractOpenURL('')<CR>
 519 nmap \w :call ExtractOpenURL('-n')<CR>
 520 nmap \t :call ExtractOpenURL('-t')<CR>
 521 " Send visual block to a browser
 522 vmap \b ""y:call OpenURL('<C-R>"', '')<CR>
 523 vmap \w ""y:call OpenURL('<C-R>"', '-n')<CR>
 524 vmap \t ""y:call OpenURL('<C-R>"', '-t')<CR>
 525 " Encode and send visual block to a browser
 526 vmap \B ""y:call EncodeOpenURL('<C-R>"', '')<CR>
 527 vmap \W ""y:call EncodeOpenURL('<C-R>"', '-n')<CR>
 528 vmap \T ""y:call EncodeOpenURL('<C-R>"', '-t')<CR>
 529 " Send current file's name to a browser
 530 nmap \B :call EncodeOpenURL('file:' . expand("%:p"), '')<CR>
 531 nmap \W :call EncodeOpenURL('file:' . expand("%:p"), '-n')<CR>
 532 nmap \T :call EncodeOpenURL('file:' . expand("%:p"), '-t')<CR>
 533
 534 endif " version >= 700
 535
 536
 537 " SPELLING
 538
 539 if has("spell") " Works in 7.0+
 540    " Use builtin spellchecker
 541    nmap \sv :syntax off <BAR> setlocal spell<CR>
 542    " Clear
 543    nmap \sn :syntax on <BAR> setlocal nospell<CR>
 544 endif
 545
 546
 547 " Russian letters mapped in normal mode
 548 "if has("keymap")
 549 "   set keymap=russian-jcuken
 550 "endif
 551
 552 if has("langmap")
 553    if v:version >= 702
 554       " langmap in utf-8 mode requires at least Vim 7.2.109
 555       scriptencoding utf-8
 556       set langmap=ё`Ё~йqцwуeкrеtнyгuшiщoзpх[ъ]фaыsвdаfпgрhоjлkдlж\\;э'
 557                  \яzчxсcмvиbтnьmб\\,ю.ЙQЦWУEКRЕTНYГUШIЩOЗPХ{Ъ}
 558                  \ФAЫSВDАFПGРHОJЛKДLЖ:Э\\"ЯZЧXСCМVИBТNЬMБ<Ю>
 559
 560    elseif &encoding != 'utf-8'
 561       scriptencoding koi8-r
 562       set langmap=ё`Ё~йqцwуeкrеtнyгuшiщoзpх[ъ]фaыsвdаfпgрhоjлkдlж\\;э'
 563                  \яzчxсcмvиbтnьmб\\,ю.ЙQЦWУEКRЕTНYГUШIЩOЗPХ{Ъ}
 564                  \ФAЫSВDАFПGРHОJЛKДLЖ:Э\\"ЯZЧXСCМVИBТNЬMБ<Ю>
 565    endif
 566
 567    scriptencoding us-ascii
 568 endif
 569
 570
 571 if version >= 700
 572 function! W()
 573    " let encodings=filter(split(&fileencodings, ','), 'v:val != "ucs-bom"')
 574    let encodings = ['us-ascii']
 575    if $LC_CTYPE =~ 'UTF-8' " UTF-8 or en_US.UTF-8 or ru_RU.UTF-8 or such
 576       let encodings += ['utf-8']
 577    elseif $LC_CTYPE == 'ru_RU.KOI8-R'
 578       let encodings += ['koi8-r', 'utf-8']
 579    elseif v:lc_time == 'Russian_Russia.1251'
 580       let encodings += ['cp1251', 'utf-8']
 581    endif
 582
 583    for e in encodings
 584       try
 585          execute 'set fileencoding=' . e
 586          w
 587          break
 588       catch /E513: write error, conversion failed/
 589          continue
 590       endtry
 591    endfor
 592
 593    if &modified
 594       throw '"' . expand('%') . '" E513: write error, conversion failed; tried ' . join(encodings, ',')
 595    elseif has("spell")
 596       call SetupSpell()
 597    endif
 598 endfunction
 599
 600 command! W call W()
 601 endif
 602
 603
 604 function! SlowTerm()
 605    set laststatus=1
 606    set noruler
 607    set shortmess=aoOtT
 608    set noshowcmd
 609    set scrolljump=5 " The minimal number of lines to scroll vertically when the cursor gets of the screen
 610    set sidescroll=5
 611    set nottyfast
 612    set notitle
 613    set timeoutlen=5000
 614    set nowildmenu
 615    set wildmode=list:longest
 616    set viminfo=!,h,'10,<100,s5
 617    if has("iconv")
 618       set viminfo+=c
 619    endif
 620    syntax off
 621    highlight NonText cterm=NONE ctermfg=NONE
 622 endfunction
 623
 624 if exists("$SLOWTERM")
 625    call SlowTerm()
 626 endif
 627
 628
 629 if has("python")
 630 pyfile ~/.vim/python/virtualenv.py
 631 endif
 632
 633 if has("python3")
 634 py3file ~/.vim/python/virtualenv.py
 635 endif
 636
 637
 638 " From Tip 212:
 639 " http://vim.fandom.com/wiki/Setting_file_attributes_without_reloading_a_buffer
 640
 641 if executable('chmod')
 642    function! SetExecutableBit(x)
 643       checktime
 644       " Avoid 'Reload Y/N?' question
 645       autocmd FileChangedShell <buffer> call _BufChangedCB()
 646       let fx = executable(expand("%:p"))
 647       if a:x && !fx
 648          silent !chmod a+x %
 649       elseif !a:x && fx
 650          silent !chmod a-x %
 651       endif
 652       if v:shell_error
 653          echoerr 'Error running chmod: ' . v:shell_error
 654       endif
 655       checktime
 656       autocmd! FileChangedShell <buffer>
 657    endfunction
 658    function! _BufChangedCB()
 659       autocmd! FileChangedShell <buffer>
 660    endfunction
 661    command! ToggleXbit if executable(expand("%:p")) | call SetExecutableBit(0) | else | call SetExecutableBit(1) | endif
 662 endif
 663
 664 function! Code()
 665     setlocal expandtab tabstop=8 softtabstop=4 shiftwidth=4
 666 endfunction
 667 command! Code call Code()
 668
 669 function! Text()
 670     setlocal expandtab tabstop=8 softtabstop=3 shiftwidth=3
 671 endfunction
 672 command! Text call Text()
 673
 674 " ----------
 675 " From http://slobin.pp.ru/vim/_vimrc.html
 676
 677 " These options will be kept between editing sessions
 678 " let options = []
 679
 680 " Called automagically after .viminfo and plugins are loaded, sets
 681 " miscellaneous options from persistent global variables
 682 " function! VimEnter()
 683   " for optname in g:options
 684   "   let varname = "g:OPT_" . toupper(optname)
 685   "   if exists(varname)
 686   "     execute "let &" . optname . " = " . varname
 687   "   endif
 688   " endfor
 689
 690   " if has("gui_running") && exists("g:WINPOSX") && exists("g:WINPOSY")
 691   "   execute "winpos" g:WINPOSX g:WINPOSY
 692   " endif
 693 " endfunction
 694
 695 " Called automagically before .viminfo is saved, saves miscellaneous
 696 " options into persistent global variables
 697 " function! VimLeavePre()
 698   " call filter(g:, 'v:key !~# "^OPT_"')
 699   " for optname in g:options
 700   "   let varname = "g:OPT_" . toupper(optname)
 701   "   execute "let " . varname . " = &g:" . optname
 702   " endfor
 703
 704   " if has("gui_running")
 705   "   let g:WINPOSX = getwinposx()
 706   "   let g:WINPOSY = getwinposy()
 707   " endif
 708 " endfunction
 709
 710 " autocmd VimEnter * call VimEnter()
 711 " autocmd VimLeavePre * call VimLeavePre()
 712
 713
 714 " Called automagically after every buffer read, enables fileencoding
 715 " setting from modeline (see Tip #911:
 716 " http://vim.fandom.com/wiki/How_to_make_fileencoding_work_in_the_modeline)
 717 function! AutoEncoding()
 718   if &modified && &fileencoding != ""
 719     call SetupEncoding(&fileencoding)
 720   endif
 721   autocmd! auto-encoding
 722   augroup! auto-encoding
 723 endfunction
 724
 725 augroup auto-encoding
 726 autocmd!
 727 autocmd BufWinEnter * call AutoEncoding()
 728 augroup END
 729
 730
 731 let CONVERT=1
 732
 733 " Value of a character under cursor; better than standard '0x%02B (%b)'
 734 function! HexDec()
 735   let char = matchstr(getline("."), ".", col(".") - 1)
 736   if g:CONVERT
 737     let char = iconv(char, &encoding, &fileencoding)
 738     let format = "0x%02X <%d>"
 739   else
 740     let format = "0x%02X (%d)"
 741   endif
 742   let char = char2nr(char)
 743   return printf(format, char, char)
 744 endfunction
 745
 746
 747 if has("iconv")
 748    " Helper function for :DecodeQP and :DecodeURL commands
 749    function! DecodeHex(arg)
 750      return iconv(printf("%c", str2nr(submatch(1), 16)), a:arg, &encoding)
 751    endfunction
 752
 753    " Custom completion for encoding names
 754    function! EncList(ArgLead, CmdLine, CursorPos)
 755      return filter(split(&fileencodings, ','),
 756                  \ "strpart(v:val, 0, strlen(a:ArgLead)) == a:ArgLead")
 757    endfunction
 758
 759    if version >= 700
 760    " Command for decoding qp-encoded text
 761    command! -bar -nargs=? -range -complete=customlist,EncList DecodeQP
 762           \ <line1>,<line2>s/=\(\x\x\|\n\)/\=DecodeHex(<q-args>)/eg
 763
 764    " Command for decoding url-encoded text
 765    command! -bar -nargs=? -range -complete=customlist,EncList DecodeURL
 766           \ <line1>,<line2>s/%\(\x\x\)/\=DecodeHex(<q-args>)/eg
 767    endif
 768 endif
 769
 770
 771 if has("spell")
 772    function! SetupSpell()
 773       if &fileencoding =~ 'ascii'
 774          setlocal spelllang=en spellfile=~/.vim/spell/en.ascii.add
 775       elseif &fileencoding == 'koi8-r'
 776          setlocal spelllang=en,ru spellfile=~/.vim/spell/en.ascii.add,~/.vim/spell/ru.koi8-r.add
 777       elseif &fileencoding == 'utf-8'
 778          setlocal spelllang=en,ru spellfile=~/.vim/spell/en.ascii.add,~/.vim/spell/ru.utf-8.add
 779       else
 780          setlocal spelllang= spellfile=
 781       endif
 782    endfunction
 783    autocmd BufReadPost * call SetupSpell()
 784
 785    function! SaveSpell()
 786       if expand('%:p') == expand('~/.vim/spell/en.ascii.add')
 787          mkspell! -ascii %
 788       else
 789          mkspell! %
 790       endif
 791    endfunction
 792    autocmd BufWritePost ~/.vim/spell/*.add call SaveSpell()
 793 endif
 794
 795
 796 function! SyntaxName()
 797   echomsg synIDattr(synID(line("."), col("."), 1), "name")
 798 endfunction
 799
 800
 801 if has("python")
 802 pyfile ~/.vim/python/completion.py
 803
 804 " Custom completion for python expressions
 805 function! CompList(ArgLead, CmdLine, CursorPos)
 806   python vim_comp_list()
 807 endfunction
 808
 809 " Python command line calculator
 810 command! -nargs=+ -range -complete=customlist,CompList Calc
 811        \ <line1>,<line2> python vim_calc(<q-args>)
 812
 813 " Python text range filter
 814 command! -nargs=+ -range -complete=customlist,CompList Pydo
 815        \ <line1>,<line2> python vim_pydo(<q-args>)
 816
 817 " Display unicode name for the character under cursor
 818 command! Uname python vim_unicode_name()
 819 endif
 820
 821 if has("python3")
 822 py3file ~/.vim/python/completion.py
 823
 824 " Custom completion for python expressions
 825 function! CompList(ArgLead, CmdLine, CursorPos)
 826   python3 vim_comp_list()
 827 endfunction
 828
 829 " Python command line calculator
 830 command! -nargs=+ -range -complete=customlist,CompList Calc
 831        \ <line1>,<line2> python3 vim_calc(<q-args>)
 832
 833 " Python text range filter
 834 command! -nargs=+ -range -complete=customlist,CompList Pydo
 835        \ <line1>,<line2> python3 vim_pydo(<q-args>)
 836
 837 " Display unicode name for the character under cursor
 838 command! Uname python3 vim_unicode_name()
 839 endif
 840
 841 if has("python") || has("python3")
 842 command! UName Uname
 843 endif
 844 " ----------
 845
 846 if v:version >= 800
 847    function! SetLazyRedraw(timer_id)
 848       call timer_stop(a:timer_id) " One-time event
 849       set lazyredraw
 850    endfunction
 851    call timer_start(500, 'SetLazyRedraw')
 852 endif
 853
 854 " This has to go to the very end of ~/.vimrc to allow reading the .vimrc
 855 set secure        " safer working with script files in the current directory