.vimrc

   1 " User configuration file for Vi IMproved.
   2 "
   3 " vim 6.0+ required, 7.0+ recommended.
   4
   5 " 1 important
   6
   7 " Remove ALL autocommands in case the file is sourced for the second time
   8 autocmd!
   9
  10 language messages C " Print messages in English
  11
  12 if exists("b:wrap") " Only do this on the second and subsequent :source's
  13    let fenc = &fileencoding
  14    let ftype = &filetype
  15    let mod = &modified
  16    set all& " Reset all options, except terminal options, to their default value.
  17    execute 'set fileencoding=' . fenc
  18    execute 'set filetype=' . ftype
  19    if mod
  20       set modified
  21    else
  22       set nomodified
  23    endif
  24    unlet fenc ftype mod
  25 endif
  26
  27 " No, it is not VI, it is VIM! It is important to set this first, because this
  28 " command resets many other options.
  29 set nocompatible
  30
  31 " Set behavior to xterm, not mswin
  32 behave xterm
  33
  34 " 2 moving around, searching and patterns
  35
  36 set ignorecase    " Ignore case in search patterns
  37 set smartcase     " Match 'word' case-insensitive and 'Word' case-sensitive
  38
  39 set nostartofline " Keep cursor's column
  40 set whichwrap=b,s,h,l,<,>,[,],~ " Wrap to the previous/next line on all keys and ~ command
  41
  42 " 4 displaying text
  43
  44 set display=lastline,uhex " Show the last line instead of '@'; show non-printable chars as <hex>
  45 set lazyredraw    " Do not update screen while executing macros
  46 set list          " listchars only works with 'list'
  47 set listchars=tab:>_,trail:_,extends:+ " Show tabs, trailing spaces, long lines
  48 set wrap          " Visually wrap long lines
  49
  50 " With 'set wrap' wrap long lines at a character in 'breakat'
  51 " Please note 'nolist' is required to use 'linebreak'
  52 set linebreak showbreak=+\ " A plus and a space
  53
  54 set sidescroll=1  " The minimal number of columns to scroll horizontally
  55
  56 " 5 highlighting
  57
  58 set nohlsearch    " Stop the search highlighting
  59
  60 " 6 multiple windows
  61
  62 set hidden        " Don't unload a buffer when no longer shown in a window; allow to switch between buffers/windows when the buffer is modified
  63 set laststatus=2  " Always show status line
  64
  65 set splitbelow    " A new window is put below of the current one
  66 set splitright    " A new window is put right of the current one
  67
  68 " 8 terminal
  69
  70 set ttyfast       " terminal connection is fast
  71
  72 set title         " Set title to the value of 'titlestring' or to 'filename - VIM'
  73 set titleold=     " string to restore the title to when exiting Vim
  74
  75 " 9 using the mouse
  76
  77 set mouse=ar      " Use mouse in all modes, plus hit-return
  78
  79 " 12 messages and info
  80
  81 set ruler         " Show cursor position below each window
  82 set showcmd       " Show (partial) command keys in the status line
  83
  84 " Short message for [Modified];
  85 " overwrite message for writing a file with subsequent message;
  86 " truncate long file messages
  87 set shortmess=mot
  88
  89 " 14 editing text
  90
  91 set backspace=indent,eol,start
  92 set complete+=k   " Scan spell dictionaries for completion in addition to standard places
  93 set infercase     " adjust case of a keyword completion match
  94 set nojoinspaces  " Do not insert two spaces after a '.', '?' and '!' with a join command
  95 set nrformats=hex " I seldom edit octal numbers, but very often dates like 2001-02-01
  96
  97 " Default value 'croql' is a compromise for both natural and programming
  98 " languages, but as any compromise it works good for neither natural nor
  99 " programming languages. This value is good for natural texts,
 100 " let ftplugins to set values suitable for programming languages.
 101 set formatoptions=2t " list of flags that tell how automatic formatting works
 102
 103 " 15 tabs and indenting
 104
 105 set expandtab     " expand <Tab> to spaces in Insert mode
 106 set shiftwidth=3  " number of spaces used for each step of (auto)indent
 107 set smarttab      " a <Tab> in an indent inserts 'shiftwidth' spaces
 108 set softtabstop=3 " number of spaces to insert for a <Tab>
 109
 110 set noautoindent  " Do not automatically set the indent of a new line
 111
 112 " 18 mapping
 113
 114 set timeout timeoutlen=3000 " allow timing out up to 3 seconds halfway into a mapping
 115
 116 " 21 command line editing
 117
 118 set history=1000  " how many command lines are remembered
 119 set suffixes+=.pyc,.pyo " list of file name extensions that have a lower priority
 120 set wildignore+=*.py[co] " Ignore these patterns when completing file names
 121 set wildmenu      " command-line completion shows a list of matches
 122 set wildmode=longest,list:longest,full " Bash-vim completion behavior
 123
 124 " 22 executing external commands
 125
 126 if has("filterpipe")
 127    set noshelltemp " Use pipes on Unix
 128 endif
 129
 130 " 25 multi-byte characters
 131
 132 " Automatically detected character encodings
 133 set fileencodings=ucs-bom,us-ascii,utf-8,koi8-r,cp1251,cp866,latin1
 134
 135 " 26 various
 136
 137 " ! - when included, save and restore global variables that start
 138 "     with an uppercase letter, and don't contain a lowercase letter;
 139 " h - disable the effect of 'hlsearch';
 140 " ' - number of files for which the marks are remembered;
 141 " " and < - maximum number of lines saved for a register;
 142 " s - maximum size of an item in Kbytes.
 143 if version < 603
 144    set viminfo=!,h,'50,\"1000
 145 else
 146    set viminfo=!,h,'50,<1000,s10
 147 endif
 148
 149 " c - convert viminfo to the current encoding;
 150 if has("iconv")
 151    set viminfo^=c
 152 endif
 153
 154 " Removable media paths
 155 if has("win32")
 156    set viminfo+=ra:,rb:
 157 endif
 158
 159 " ----------
 160
 161 if has("gui_running")
 162    set background=light
 163
 164    if has("win32")
 165       "set guifont=Courier_New:h18:cRUSSIAN
 166       set guifont=Lucida_Console:h18:cRUSSIAN
 167    else
 168       set guifont=Monospace\ 16
 169       set toolbar=icons,text " how to show the toolbar
 170    endif
 171
 172    " set guicursor+=a:blinkon0 " Stop cursor blinking
 173
 174    " Make shift-insert work like in Xterm
 175    " map <S-Insert> <MiddleMouse>
 176    " map! <S-Insert> <MiddleMouse>
 177
 178
 179    " Set nice colors
 180    " Background for normal text is light grey
 181    " Cursor is green
 182    " Text below the last line is darker grey
 183    " Status line is bright white on blue
 184    highlight Normal guibg=grey90
 185    highlight Cursor guibg=green guifg=NONE
 186    highlight NonText guibg=grey80
 187    highlight Constant guibg=grey90
 188    highlight Special gui=NONE guibg=grey90
 189    highlight StatusLine gui=bold guifg=white guibg=blue
 190
 191    " ----------
 192    " From http://slobin.pp.ru/vim/_vimrc.html
 193
 194    " Arrows should go into wrapped lines, but not while popup menu is visible
 195    imap <expr> <Down> pumvisible() ? "<Down>" : "<C-O>gj"
 196    imap <expr> <Up> pumvisible() ? "<Up>" : "<C-O>gk"
 197
 198    " The <CR> key should select from completion menu without adding a newline
 199    imap <expr> <CR> pumvisible() ? "<C-Y>" : "<CR>"
 200    " ----------
 201 else
 202
 203    if (&term =~ "linux") || ($BACKGROUND == 'DARK') || ($BACKGROUND == 'dark')
 204          \ || has("win32")
 205       " Background of the terminal is black or dark grey
 206       set background=dark
 207    else
 208       set background=light
 209    endif
 210
 211    if (&term =~ "linux")
 212       set <BS>=\7f
 213    else
 214       highlight MoreMsg cterm=bold ctermfg=NONE
 215       highlight Question cterm=bold ctermfg=NONE
 216    endif
 217
 218    if (&term =~ "term") || (&term =~ "rxvt") || (&term =~ "vt100") || (&term =~ "screen")
 219       set <BS>=\7f
 220
 221       " 'autoselect' to always put selected text on the clipboard;
 222       " 'unnamed' to use the * register like unnamed register '*'
 223       " for all yank, delete and put operations;
 224       " This allows to use mouse for copy/paste in local xterm,
 225       " but prevents to save the unnamed register between sessions.
 226       " set clipboard=autoselect,unnamed,exclude:cons\|linux
 227
 228       if has ("terminfo")
 229          " set t_Co=256
 230          set t_Co=16
 231       else
 232          set t_Co=8
 233          set t_Sf="\e[3%dm"
 234          set t_Sb="\e[4%dm"
 235       endif
 236    endif
 237
 238    if (&term =~ "screen")
 239       set ttymouse=xterm " Enable mouse codes under GNU screen
 240       if empty(&t_ts)
 241          " Enable window title under screen/tmux
 242          let &t_ts = "\e]2;"
 243          let &t_fs = "\007"
 244       endif
 245    endif
 246 endif
 247
 248 highlight SpellBad term=underline cterm=NONE ctermfg=white ctermbg=red guifg=white guibg=red " gui=undercurl guisp=red
 249 highlight StatusLine cterm=bold ctermfg=white ctermbg=blue gui=NONE guifg=white guibg=blue
 250 highlight Visual cterm=NONE ctermfg=white ctermbg=blue gui=NONE guifg=white guibg=blue " Selection highlighting
 251
 252 " Multiline comments often confuse vim syntax highlighting - these maps
 253 " allow to resynchronize; the first is faster, the second is more thorough
 254 nmap \sc :syntax sync clear<Enter>
 255 nmap \ss :syntax sync fromstart<Enter>
 256
 257
 258 " AUTOCOMMANDS
 259
 260 " Enable filetype detection
 261 filetype plugin indent on
 262
 263 " Reread me after editing
 264 autocmd BufWritePost ~/.vimrc source ~/.vimrc | syntax on
 265
 266 if version >= 700
 267 " Save all files before running any quickfix command (grep, makeprg, etc.)
 268 autocmd QuickFixCmdPre * wall
 269 endif
 270
 271 " Syntax highlighting
 272 autocmd BufReadPost * syntax on
 273
 274
 275 " Restore last known cursor position
 276 function! RestorePosition()
 277    if exists('b:position_resored')
 278       return
 279    endif
 280
 281    if line("'\"") > 0
 282       call cursor(line("'\""), col("'\""))
 283    endif
 284    let b:position_resored = 1
 285 endfunction
 286
 287 " When editing a file, always jump to the last cursor position (if saved)
 288 autocmd BufReadPost * call RestorePosition()
 289
 290
 291 function! SetupEncoding(encoding)
 292    if !has("iconv") || exists('b:encoding_set')
 293       return
 294    endif
 295
 296    if strlen(a:encoding) > 0
 297       call RestorePosition()
 298       let b:encoding_set = 1
 299       execute "edit ++enc=" . a:encoding
 300    endif
 301 endfunction
 302
 303
 304 " http://lwn.net/Articles/226514/
 305
 306 augroup gpg
 307 " Remove ALL autocommands for the current group.
 308 autocmd!
 309 autocmd BufReadPre,FileReadPre *.gpg set viminfo=
 310 autocmd BufReadPre,FileReadPre *.gpg setlocal noswapfile
 311 autocmd BufReadPost *.gpg :%!gpg -q -d
 312 autocmd BufReadPost *.gpg | redraw
 313 autocmd BufWritePre *.gpg :%!gpg --default-recipient-self -q -e -a
 314 autocmd BufWritePost *.gpg u
 315 autocmd VimLeave *.gpg :!clear
 316 " For OpenSSL:
 317 " BufReadPost: use "openssl bf -d -a"
 318 " BufWritePre: use "openssl bf -salt -a"
 319 augroup END
 320
 321
 322 function! SetWrap()
 323    setlocal wrap
 324    map <Up> gk
 325    imap <Up> <C-O>gk
 326    map <Down> gj
 327    imap <Down> <C-O>gj
 328    let b:wrap = 1
 329 endfunction
 330
 331 function! SetNoWrap()
 332    setlocal nowrap
 333    map <Up> k
 334    map <Down> j
 335    let b:wrap = 0
 336 endfunction
 337
 338 command! SetWrap call SetWrap()
 339 command! SetNoWrap call SetNoWrap()
 340
 341 " b:wrap can be set by an ftplugin
 342 autocmd BufReadPost * if !exists("b:wrap") | call SetWrap() | endif
 343
 344
 345 " MAPPINGS
 346
 347 " Do not unindent #-comment
 348 inoremap # X<C-H>#
 349
 350 " map <C-A> <Home>
 351 " map <C-E> <End>
 352 " map <C-Z> :shell<CR>
 353
 354
 355 if version >= 700
 356 " WEB BROWSERS
 357
 358 let s:URL_re="\\v(((https?|ftp|gopher|telnet)://|(mailto|file|news|about|ed2k|irc|sip|magnet):)[^' \t<>\"]+|(www|web|w3)[a-z0-9_-]*\\.[a-z0-9._-]+\\.[^' \t<>\"]+)[a-z0-9/]\\c"
 359
 360 function! ExtractURL()
 361    let line = getline('.')
 362    let parts = split(line, s:URL_re . '\zs')
 363
 364    if len(parts) == 0
 365       throw 'ExtractURLCannotFindURL' " No URL found
 366    endif
 367
 368    let length = 0
 369    let column = col('.')
 370
 371    for p in parts
 372       let save_length = length
 373       let length += len(p)
 374       if length >= column
 375          break
 376       endif
 377    endfor
 378
 379    let pos = match(p, s:URL_re)
 380    if pos == -1
 381       throw 'ExtractURLCannotFindURL' " No URL found
 382    endif
 383
 384    if save_length + pos >= column " cursor left of the URL
 385       throw 'ExtractURLCannotFindURL'
 386    endif
 387
 388    return strpart(p, pos)
 389 endfunction
 390
 391 function! EscapeURL(url)
 392    let url = substitute(a:url, ' ', '%20', 'g')
 393    return escape(url, '!#$%')
 394 endfunction
 395
 396 function! OpenURL(url, newwin)
 397    execute "!webbrowser " . a:newwin . " '" . EscapeURL(a:url) . "'"
 398 endfunction
 399
 400 function! ExtractOpenURL(newwin)
 401    try
 402       let url = ExtractURL()
 403    catch /^ExtractURLCannotFindURL$/
 404       echoerr 'No URL found under cursor'
 405       return
 406    endtry
 407
 408    call OpenURL(url, a:newwin)
 409 endfunction
 410
 411 function! EncodeOpenURL(url, newwin)
 412    execute "!webbrowser-encode-url " . a:newwin . " '" . EscapeURL(a:url) . "'"
 413 endfunction
 414
 415
 416 " Send current link to a browser
 417 nmap \b :call ExtractOpenURL('')<CR>
 418 nmap \w :call ExtractOpenURL('-n')<CR>
 419 nmap \t :call ExtractOpenURL('-t')<CR>
 420 " Send visual block to a browser
 421 vmap \b ""y:call OpenURL('<C-R>"', '')<CR>
 422 vmap \w ""y:call OpenURL('<C-R>"', '-n')<CR>
 423 vmap \t ""y:call OpenURL('<C-R>"', '-t')<CR>
 424 " Encode and send visual block to a browser
 425 vmap \B ""y:call EncodeOpenURL('<C-R>"', '')<CR>
 426 vmap \W ""y:call EncodeOpenURL('<C-R>"', '-n')<CR>
 427 vmap \T ""y:call EncodeOpenURL('<C-R>"', '-t')<CR>
 428 " Send current file's name to a browser
 429 nmap \B :call EncodeOpenURL('file:' . expand("%:p"), '')<CR>
 430 nmap \W :call EncodeOpenURL('file:' . expand("%:p"), '-n')<CR>
 431 nmap \T :call EncodeOpenURL('file:' . expand("%:p"), '-t')<CR>
 432
 433 endif " version >= 700
 434
 435
 436 " SPELLING
 437
 438 if has("spell") " Works in 7.0+
 439    " Use builtin spellchecker
 440    nmap \sv :syntax off <BAR> setlocal spell<CR>
 441    " Clear
 442    nmap \sn :syntax on <BAR> setlocal nospell<CR>
 443 endif
 444
 445
 446 " Russian letters mapped in normal mode
 447 "if has("keymap")
 448 "   set keymap=russian-jcuken
 449 "endif
 450
 451 if has("langmap")
 452    if v:version >= 702
 453       " langmap in utf-8 mode requires at least Vim 7.2.109
 454       scriptencoding utf-8
 455       set langmap=ё`Ё~йqцwуeкrеtнyгuшiщoзpх[ъ]фaыsвdаfпgрhоjлkдlж\\;э'
 456                  \яzчxсcмvиbтnьmб\\,ю.ЙQЦWУEКRЕTНYГUШIЩOЗPХ{Ъ}
 457                  \ФAЫSВDАFПGРHОJЛKДLЖ:Э\\"ЯZЧXСCМVИBТNЬMБ<Ю>
 458
 459    elseif &encoding != 'utf-8'
 460       scriptencoding koi8-r
 461       set langmap=ё`Ё~йqцwуeкrеtнyгuшiщoзpх[ъ]фaыsвdаfпgрhоjлkдlж\\;э'
 462                  \яzчxсcмvиbтnьmб\\,ю.ЙQЦWУEКRЕTНYГUШIЩOЗPХ{Ъ}
 463                  \ФAЫSВDАFПGРHОJЛKДLЖ:Э\\"ЯZЧXСCМVИBТNЬMБ<Ю>
 464    endif
 465
 466    scriptencoding us-ascii
 467 endif
 468
 469
 470 if version >= 700
 471 function! W()
 472    " let encodings=filter(split(&fileencodings, ','), 'v:val != "ucs-bom"')
 473    let encodings = ['us-ascii']
 474    if $LC_CTYPE == 'ru_RU.UTF-8'
 475       let encodings += ['utf-8']
 476    elseif $LC_CTYPE == 'ru_RU.KOI8-R'
 477       let encodings += ['koi8-r', 'utf-8']
 478    elseif v:lc_time == 'Russian_Russia.1251'
 479       let encodings += ['cp1251', 'utf-8']
 480    endif
 481
 482    for e in encodings
 483       try
 484          execute 'set fileencoding=' . e
 485          w
 486          break
 487       catch /E513: write error, conversion failed/
 488          continue
 489       endtry
 490    endfor
 491
 492    if &modified
 493       throw '"' . expand('%') . '" E513: write error, conversion failed; tried ' . join(encodings, ',')
 494    elseif has("spell")
 495       call SetupSpell()
 496    endif
 497 endfunction
 498
 499 command! W call W()
 500 endif
 501
 502
 503 function! SlowTerm()
 504    set laststatus=1
 505    set noruler
 506    set shortmess=aoOtT
 507    set noshowcmd
 508    set scrolljump=5 " The minimal number of lines to scroll vertically when the cursor gets of the screen
 509    set sidescroll=5
 510    set nottyfast
 511    set notitle
 512    set timeoutlen=5000
 513    set nowildmenu
 514    set wildmode=list:longest
 515    set viminfo=!,h,'10,<100,s5
 516    syntax off
 517    highlight NonText cterm=NONE ctermfg=NONE
 518 endfunction
 519
 520 if exists("$SLOWTERM")
 521    call SlowTerm()
 522 endif
 523
 524
 525 " ----------
 526 " From http://slobin.pp.ru/vim/_vimrc.html
 527
 528 " These options will be kept between editing sessions
 529 " let options = []
 530
 531 " Called automagically after .viminfo and plugins are loaded, sets
 532 " miscellaneous options from persistent global variables
 533 " function! VimEnter()
 534   " for optname in g:options
 535   "   let varname = "g:OPT_" . toupper(optname)
 536   "   if exists(varname)
 537   "     execute "let &" . optname . " = " . varname
 538   "   endif
 539   " endfor
 540
 541   " if has("gui_running") && exists("g:WINPOSX") && exists("g:WINPOSY")
 542   "   execute "winpos" g:WINPOSX g:WINPOSY
 543   " endif
 544 " endfunction
 545
 546 " Called automagically before .viminfo is saved, saves miscellaneous
 547 " options into persistent global variables
 548 " function! VimLeavePre()
 549   " call filter(g:, 'v:key !~# "^OPT_"')
 550   " for optname in g:options
 551   "   let varname = "g:OPT_" . toupper(optname)
 552   "   execute "let " . varname . " = &g:" . optname
 553   " endfor
 554
 555   " if has("gui_running")
 556   "   let g:WINPOSX = getwinposx()
 557   "   let g:WINPOSY = getwinposy()
 558   " endif
 559 " endfunction
 560
 561 " autocmd VimEnter * call VimEnter()
 562 " autocmd VimLeavePre * call VimLeavePre()
 563
 564
 565 " Called automagically after every buffer read, enables fileencoding
 566 " setting from modeline (see Tip #911)
 567 function! AutoEncoding()
 568   if exists("b:justloaded")
 569     unlet b:justloaded
 570     if &modified && &fileencoding != ""
 571       call SetupEncoding(&fileencoding)
 572     endif
 573   endif
 574 endfunction
 575
 576 " Magic autocommands installed here
 577 autocmd BufReadPost * let b:justloaded = 1
 578 autocmd BufWinEnter * call AutoEncoding()
 579
 580
 581 let CONVERT=1
 582
 583 " Value of a character under cursor; better than standard '0x%02B (%b)'
 584 function! HexDec()
 585   let char = matchstr(getline("."), ".", col(".") - 1)
 586   if g:CONVERT
 587     let char = iconv(char, &encoding, &fileencoding)
 588     let format = "0x%02X <%d>"
 589   else
 590     let format = "0x%02X (%d)"
 591   endif
 592   let char = char2nr(char)
 593   return printf(format, char, char)
 594 endfunction
 595
 596
 597 if has("iconv")
 598    " Helper function for :DecodeQP and :DecodeURL commands
 599    function! DecodeHex(arg)
 600      return iconv(printf("%c", str2nr(submatch(1), 16)), a:arg, &encoding)
 601    endfunction
 602
 603    " Custom completion for encoding names
 604    function! EncList(ArgLead, CmdLine, CursorPos)
 605      return filter(split(&fileencodings, ','),
 606                  \ "strpart(v:val, 0, strlen(a:ArgLead)) == a:ArgLead")
 607    endfunction
 608
 609    if version >= 700
 610    " Command for decoding qp-encoded text
 611    command! -bar -nargs=? -range -complete=customlist,EncList DecodeQP
 612           \ <line1>,<line2>s/=\(\x\x\|\n\)/\=DecodeHex(<q-args>)/eg
 613
 614    " Command for decoding url-encoded text
 615    command! -bar -nargs=? -range -complete=customlist,EncList DecodeURL
 616           \ <line1>,<line2>s/%\(\x\x\)/\=DecodeHex(<q-args>)/eg
 617    endif
 618 endif
 619
 620
 621 if has("spell")
 622    function! SetupSpell()
 623       if &fileencoding =~ 'ascii'
 624          setlocal spelllang=en spellfile=~/.vim/spell/en.ascii.add
 625       elseif &fileencoding == 'koi8-r'
 626          setlocal spelllang=en,ru spellfile=~/.vim/spell/en.ascii.add,~/.vim/spell/ru.koi8-r.add
 627       elseif &fileencoding == 'utf-8'
 628          setlocal spelllang=en,ru spellfile=~/.vim/spell/en.ascii.add,~/.vim/spell/ru.utf-8.add
 629       else
 630          setlocal spelllang= spellfile=
 631       endif
 632    endfunction
 633    autocmd BufReadPost * call SetupSpell()
 634 endif
 635
 636
 637 function! SyntaxName()
 638   echomsg synIDattr(synID(line("."), col("."), 1), "name")
 639 endfunction
 640
 641
 642 if has("python")
 643
 644 python << END_OF_PYTHON
 645
 646 import sys, rlcompleter, unicodedata, vim
 647 from itertools import *
 648 vim_complete = rlcompleter.Completer().complete
 649
 650 def vim_comp_list():
 651   """Implementation of CompList() function"""
 652   arglead = vim.eval("a:ArgLead")
 653   fence = int(vim.eval("match(a:ArgLead, '\(\w\|\.\)*$')"))
 654   left, right = arglead[:fence], arglead[fence:]
 655   try:
 656     completions = (vim_complete(right, i) for i in count())
 657     candidates = list(takewhile(bool, completions))
 658   except NameError:
 659     candidates = []
 660   suggestions = [left + x for x in candidates]
 661   vim.command("return " + repr(suggestions))
 662
 663 def vim_calc(command):
 664   """Implementation of :Calc command"""
 665   global _
 666   try:
 667     result = eval(command)
 668   except SyntaxError:
 669     exec command in globals()
 670   else:
 671     if result != None:
 672       print result
 673       _ = result
 674       xx = ''.join('\\x%02x' % ord(x) for x in str(_))
 675       vim.command('let @" = "%s"' % xx)
 676
 677 def vim_pydo(command):
 678   """Implementation of :Pydo command"""
 679   codeobj = compile(command, "command", "eval")
 680   line1 = vim.current.range.start
 681   line2 = vim.current.range.end
 682   delta = 0
 683   for numz in range(line1, line2+1):
 684     line = vim.current.buffer[numz-delta]
 685     uline = unicode(line, vim.eval('&fileencoding'))
 686     num = numz + 1
 687     words = line.split()
 688     result = eval(codeobj, globals(), locals())
 689     if result is None or result is False:
 690       del vim.current.buffer[numz-delta]
 691       delta += 1
 692       continue
 693     if isinstance(result, list) or isinstance(result, tuple):
 694       result = " ".join(map(str, result))
 695     else:
 696       result = str(result)
 697     vim.current.buffer[numz-delta] = result
 698
 699 def vim_unicode_name():
 700   try:
 701     char = vim.eval("matchstr(getline('.'), '.', col('.') - 1)")
 702     print map(unicodedata.name, char.decode(vim.eval("&encoding")))
 703   except (AttributeError, ValueError), target:
 704     print "%s: %s" % (target.__class__.__name__, target.message)
 705
 706 END_OF_PYTHON
 707
 708 " Custom completion for python expressions
 709 function! CompList(ArgLead, CmdLine, CursorPos)
 710   python vim_comp_list()
 711 endfunction
 712
 713 " Python command line calculator
 714 command! -nargs=+ -range -complete=customlist,CompList Calc
 715        \ <line1>,<line2> python vim_calc(<q-args>)
 716
 717 " Python text range filter
 718 command! -nargs=+ -range -complete=customlist,CompList Pydo
 719        \ <line1>,<line2> python vim_pydo(<q-args>)
 720
 721 " Display unicode name for the character under cursor
 722 command! Uname python vim_unicode_name()
 723 command! UName call Uname()
 724
 725 endif
 726 " ----------
 727
 728
 729 " This has to go to the very end of ~/.vimrc to allow reading the .vimrc
 730 set secure        " safer working with script files in the current directory