.vimrc

   1 " User configuration file for Vi IMproved.
   2 "
   3 " vim 6.0+ required, 7.0+ recommended.
   4
   5 " 1 important
   6
   7 " Remove ALL autocommands in case the file is sourced for the second time
   8 autocmd!
   9
  10 language messages C " Print messages in English
  11
  12 if exists("b:wrap") " Only do this on the second and subsequent :source's
  13    let fenc = &fileencoding
  14    let ftype = &filetype
  15    let mod = &modified
  16    set all& " Reset all options, except terminal options, to their default value.
  17    execute 'set fileencoding=' . fenc
  18    execute 'set filetype=' . ftype
  19    if mod
  20       set modified
  21    else
  22       set nomodified
  23    endif
  24    unlet fenc ftype mod
  25
  26 elseif filereadable($VIMRUNTIME . "/defaults.vim")
  27    unlet! skip_defaults_vim
  28    source $VIMRUNTIME/defaults.vim
  29 endif
  30
  31 " No, it is not VI, it is VIM! It is important to set this first, because this
  32 " command resets many other options.
  33 set nocompatible
  34
  35 " Set behavior to xterm, not mswin
  36 behave xterm
  37
  38 " 2 moving around, searching and patterns
  39
  40 set ignorecase    " Ignore case in search patterns
  41 set noincsearch   " No incremental searching
  42 set smartcase     " Match 'word' case-insensitive and 'Word' case-sensitive
  43
  44 set nostartofline " Keep cursor's column
  45 set whichwrap=b,s,h,l,<,>,[,],~ " Wrap to the previous/next line on all keys and ~ command
  46
  47 " 4 displaying text
  48
  49 set display=lastline,uhex " Show the last line instead of '@'; show non-printable chars as <hex>
  50 set lazyredraw    " Do not update screen while executing macros
  51 set list          " listchars only works with 'list'
  52 " Show tabs, non-breaking/trailing spaces, long lines
  53 set listchars=tab:>_,nbsp:_,trail:_,extends:+,precedes:+
  54 " Another usefull additions: eol:$,space:_
  55 set scrolloff=0 " number of screen lines to show around the cursor
  56 set wrap          " Visually wrap long lines
  57
  58 " With 'set wrap' wrap long lines at a character in 'breakat'
  59 " Please note 'nolist' is required to use 'linebreak'
  60 set linebreak showbreak=+\ " A plus and a space
  61
  62 set sidescroll=1  " The minimal number of columns to scroll horizontally
  63
  64 " 5 highlighting
  65
  66 colorscheme phd
  67 set nohlsearch    " Stop the search highlighting
  68
  69 " 6 multiple windows
  70
  71 set hidden        " Don't unload a buffer when no longer shown in a window; allow to switch between buffers/windows when the buffer is modified
  72 set laststatus=2  " Always show status line
  73
  74 set splitbelow    " A new window is put below of the current one
  75 set splitright    " A new window is put right of the current one
  76
  77 " 8 terminal
  78
  79 set ttyfast       " terminal connection is fast
  80
  81 set title         " Set title to the value of 'titlestring' or to 'filename - VIM'
  82 set titleold=     " string to restore the title to when exiting Vim
  83 " String to use for the Vim window title; with statusline printf items:
  84 " display filename, modification flag, full path, argument list status,
  85 " the current user, host and program name (to distinguish vim/view/etc).
  86 set titlestring=%t%(\ %M%)%(\ (%{expand(\"%:p:h\")})%)%(\ %a%)\ -\ [%{$USER}@%{hostname()}]\ %{v:progname}
  87
  88 " 9 using the mouse
  89
  90 if has('mouse')
  91    set mouse=ar      " Use mouse in all modes, plus hit-return
  92 endif
  93
  94 " 12 messages and info
  95
  96 set ruler         " Show cursor position below each window
  97 set showcmd       " Show (partial) command keys in the status line
  98
  99 " Short message for [Modified];
 100 " overwrite message for writing a file with subsequent message;
 101 " truncate long file messages
 102 set shortmess=mot
 103
 104 " 14 editing text
 105
 106 set backspace=indent,eol,start
 107 set complete+=k   " Scan spell dictionaries for completion in addition to standard places
 108 set infercase     " adjust case of a keyword completion match
 109 set nojoinspaces  " Do not insert two spaces after a '.', '?' and '!' with a join command
 110 set nrformats=hex " I seldom edit octal numbers, but very often dates like 2001-02-01
 111
 112 " Default value 'croql' is a compromise for both natural and programming
 113 " languages, but as any compromise it works good for neither natural nor
 114 " programming languages. This value is good for natural texts,
 115 " let ftplugins to set values suitable for programming languages.
 116 set formatoptions=2t " list of flags that tell how automatic formatting works
 117
 118 " 15 tabs and indenting
 119
 120 set expandtab     " expand <Tab> to spaces in Insert mode
 121 set shiftwidth=3  " number of spaces used for each step of (auto)indent
 122 set smarttab      " a <Tab> in an indent inserts 'shiftwidth' spaces
 123 set softtabstop=3 " number of spaces to insert for a <Tab>
 124
 125 set noautoindent  " Do not automatically set the indent of a new line
 126
 127 " 18 mapping
 128
 129 set timeout timeoutlen=3000 ttimeoutlen=100 " allow timing out up to 3 seconds halfway into a mapping; 100 ms to wait for a key code or mapped key sequence to complete
 130
 131 " 19 reading and writing files
 132 if v:version >= 703
 133    set cryptmethod=blowfish " encryption method for file writing: zip or blowfish
 134 endif
 135
 136 " 20 the swap file
 137
 138 let myUndoDir = expand('~/tmp/vim/undo')
 139 if !isdirectory(myUndoDir)
 140     " Create dirs
 141     call mkdir(myUndoDir, 'p')
 142 endif
 143
 144 " list of directories for the swap file; remove . (the current directory)
 145 if has("win32")
 146    set directory=~/tmp/vim//,$TEMP//,c:/tmp//,c:/temp//
 147 else
 148    set directory=~/tmp/vim//,~/tmp//,/var/tmp//,/tmp//
 149 endif
 150 " if a directory ends in two path separators "//"
 151 " or "\\", the swap file name will be built from the complete path to
 152 " the file with all path separators substituted to percent '%' signs.
 153 " This will ensure file name uniqueness in the preserve directory.
 154
 155 " 21 command line editing
 156
 157 set history=1000  " how many command lines are remembered
 158 set suffixes+=.pyc,.pyo " list of file name extensions that have a lower priority
 159 set wildignore+=*.py[co] " Ignore these patterns when completing file names
 160 set wildmenu      " command-line completion shows a list of matches
 161 set wildmode=longest,list:longest,full " Bash-vim completion behavior
 162
 163 " Keep undo history across sessions by storing it in a file
 164 if has('persistent_undo')
 165     let &undodir = myUndoDir
 166     set undofile
 167 endif
 168
 169 " 22 executing external commands
 170
 171 if has("filterpipe")
 172    set noshelltemp " Use pipes on Unix
 173 endif
 174
 175 " 25 multi-byte characters
 176
 177 " Automatically detected character encodings
 178 set fileencodings=ucs-bom,us-ascii,utf-8,koi8-r,cp1251,cp866,latin1
 179
 180 " 26 various
 181
 182 " ! - when included, save and restore global variables that start
 183 "     with an uppercase letter, and don't contain a lowercase letter;
 184 " h - disable the effect of 'hlsearch';
 185 " ' - number of files for which the marks are remembered;
 186 " " and < - maximum number of lines saved for a register;
 187 " s - maximum size of an item in Kbytes.
 188 set viminfo=!,h,'50
 189 if version < 603
 190    set viminfo+=\"1000
 191 else
 192    set viminfo+=<1000,s10
 193 endif
 194
 195 " c - convert viminfo to the current encoding;
 196 if has("iconv")
 197    set viminfo+=c
 198 endif
 199
 200 " Removable media paths
 201 if has("win32")
 202    set viminfo+=ra:,rb:
 203 endif
 204
 205 " ----------
 206
 207 if has("gui_running")
 208    set background=light
 209
 210    if has("win32")
 211       "set guifont=Courier_New:h18:cRUSSIAN
 212       set guifont=Lucida_Console:h18:cRUSSIAN
 213    else
 214       set guifont=Monospace\ 16
 215       set toolbar=icons,text " how to show the toolbar
 216    endif
 217
 218    set guicursor+=a:blinkon0 " Stop cursor blinking
 219
 220    " Make shift-insert work like in Xterm
 221    " map <S-Insert> <MiddleMouse>
 222    " map! <S-Insert> <MiddleMouse>
 223
 224    " ----------
 225    " From http://slobin.pp.ru/vim/_vimrc.html
 226
 227    " Arrows should go into wrapped lines, but not while popup menu is visible
 228    imap <expr> <Down> pumvisible() ? "<Down>" : "<C-O>gj"
 229    imap <expr> <Up> pumvisible() ? "<Up>" : "<C-O>gk"
 230
 231    " The <CR> key should select from completion menu without adding a newline
 232    imap <expr> <CR> pumvisible() ? "<C-Y>" : "<CR>"
 233    " ----------
 234
 235 else
 236    if (&term =~ "linux") || ($BACKGROUND == 'DARK') || ($BACKGROUND == 'dark')
 237          \ || has("win32")
 238       " Background of the terminal is black or dark grey
 239       set background=dark
 240    else
 241       set background=light
 242    endif
 243
 244    if (&term =~ "linux")
 245       execute 'set t_kb=' . nr2char(127)
 246    endif
 247
 248    if (&term =~ "rxvt") || (&term =~ "screen") || (&term =~ "term") || (&term =~ "vt100")
 249       execute 'set t_kb=' . nr2char(127)
 250
 251       if has ("terminfo")
 252          " set t_Co=256
 253          set t_Co=16
 254       else
 255          set t_Co=8
 256          set t_Sf="\e[3%dm"
 257          set t_Sb="\e[4%dm"
 258       endif
 259
 260       " 'autoselect' to always put selected text on the clipboard;
 261       " 'unnamed' to use the * register like unnamed register '*'
 262       " for all yank, delete and put operations;
 263       " This allows to use mouse for copy/paste in local xterm,
 264       " but prevents to save the unnamed register between sessions.
 265       " set clipboard=autoselect,unnamed,exclude:cons\|linux
 266
 267       " Use xclip to copy/paste to/from X clipboard at remote host
 268       " vmap "+y :!xclip -i -sel clip
 269       " map "+p :r!xclip -o -sel clip
 270       " Enable X11Forwarding and use ssh -X or even -Y
 271    endif
 272
 273    if (&term =~ "screen")
 274       set ttymouse=xterm2 " Enable mouse codes under screen/tmux
 275       if empty(&t_ts)
 276          " Enable window title under screen/tmux
 277          let &t_ts = "\e]2;"
 278          let &t_fs = "\007"
 279       endif
 280    endif
 281
 282    " Bracketed paste mode
 283    " https://github.com/ConradIrwin/vim-bracketed-paste/blob/master/plugin/bracketed-paste.vim
 284    let &t_ti .= "\<Esc>[?2004h"
 285    let &t_te = "\e[?2004l" . &t_te
 286
 287    function! XTermPasteBegin(ret)
 288      set pastetoggle=<f29>
 289      set paste
 290      return a:ret
 291    endfunction
 292
 293    execute "set <f28>=\<Esc>[200~"
 294    execute "set <f29>=\<Esc>[201~"
 295    map <expr> <f28> XTermPasteBegin("i")
 296    imap <expr> <f28> XTermPasteBegin("")
 297    vmap <expr> <f28> XTermPasteBegin("c")
 298    cmap <f28> <nop>
 299    cmap <f29> <nop>
 300
 301    " https://vim.fandom.com/wiki/Change_cursor_shape_in_different_modes
 302    let &t_EI.="\e[2 q" "EI = NORMAL mode (ELSE)
 303    let &t_SI.="\e[6 q" "SI = INSERT mode
 304    let &t_SR.="\e[4 q" "SR = REPLACE mode
 305
 306    "Cursor settings:
 307    "  1 -> blinking block
 308    "  2 -> solid block
 309    "  3 -> blinking underscore
 310    "  4 -> solid underscore
 311    "  5 -> blinking vertical bar
 312    "  6 -> solid vertical bar
 313 endif
 314
 315 " Multiline comments often confuse vim syntax highlighting - these maps
 316 " allow to resynchronize; the first is faster, the second is more thorough
 317 nmap \sc :syntax sync clear<Enter>
 318 nmap \ss :syntax sync fromstart<Enter>
 319
 320
 321 " AUTOCOMMANDS
 322
 323 " Enable filetype detection
 324 filetype plugin indent on
 325
 326 runtime macros/matchit.vim
 327
 328 " Reread me after editing
 329 autocmd BufWritePost ~/.vimrc source ~/.vimrc | syntax on
 330
 331 if version >= 700
 332 " Save all files before running any quickfix command (grep, makeprg, etc.)
 333 autocmd QuickFixCmdPre * wall
 334 " automatically close quickfix if it's the only window left
 335 autocmd WinEnter * if winnr('$') == 1 &&
 336    \ index(["nofile", "quickfix"], &buftype) >= 0 | quit | endif
 337 endif
 338
 339 " Syntax highlighting
 340 autocmd BufReadPost * syntax on
 341
 342
 343 " Restore last known cursor position
 344 function! RestorePosition()
 345    if exists('b:position_restored')
 346       return
 347    endif
 348
 349    if line("'\"") > 0
 350       call cursor(line("'\""), col("'\""))
 351    endif
 352    let b:position_restored = 1
 353 endfunction
 354
 355 " When editing a file, always jump to the last cursor position (if saved)
 356 autocmd BufReadPost * call RestorePosition()
 357
 358
 359 function! SetupEncoding(encoding)
 360    if !has("iconv") || exists('b:encoding_set') || strlen(a:encoding) == 0
 361       return
 362    endif
 363
 364    call RestorePosition()
 365    let b:encoding_set = 1
 366    if len(expand('%'))
 367       execute "edit ++enc=" . a:encoding
 368    endif
 369 endfunction
 370
 371
 372 " From http://lwn.net/Articles/226514/
 373
 374 augroup gpg
 375 " Remove ALL autocommands for the current group.
 376 autocmd!
 377 autocmd BufReadPre,FileReadPre *.gpg set viminfo=
 378 autocmd BufReadPre,FileReadPre *.gpg setlocal noswapfile
 379 autocmd BufReadPost *.gpg :%!gpg -q -d
 380 autocmd BufReadPost *.gpg | redraw
 381 autocmd BufWritePre *.gpg :%!gpg --default-recipient-self -q -e -a
 382 autocmd BufWritePost *.gpg u
 383 autocmd VimLeave *.gpg :!clear
 384 " For OpenSSL:
 385 " BufReadPost: use "openssl bf -d -a"
 386 " BufWritePre: use "openssl bf -salt -a"
 387 augroup END
 388
 389
 390 function! SetWrap()
 391    setlocal wrap
 392    map <Up> gk
 393    imap <Up> <C-O>gk
 394    map <Down> gj
 395    imap <Down> <C-O>gj
 396    let b:wrap = 1
 397 endfunction
 398
 399 function! SetNoWrap()
 400    setlocal nowrap
 401    map <Up> k
 402    map <Down> j
 403    let b:wrap = 0
 404 endfunction
 405
 406 command! SetWrap call SetWrap()
 407 command! SetNoWrap call SetNoWrap()
 408
 409 " b:wrap can be set by an ftplugin
 410 autocmd BufReadPost * if !exists("b:wrap") | call SetWrap() | endif
 411
 412
 413 " MAPPINGS
 414
 415 " Do not unindent #-comment
 416 inoremap # X<C-H>#
 417
 418 " map <C-A> <Home>
 419 " map <C-E> <End>
 420 " map <C-Z> :shell<CR>
 421
 422
 423 if version >= 700
 424 " WEB BROWSERS
 425
 426 let s:URL_re="\\v(((https?|ftp|gopher|telnet)://|(mailto|file|news|about|ed2k|irc|sip|magnet):)[^' \t<>\"]+|(www|web|w3)[a-z0-9_-]*\\.[a-z0-9._-]+\\.[^' \t<>\"]+)[a-z0-9/]\\c"
 427
 428 function! ExtractURL()
 429    let line = getline('.')
 430    let parts = split(line, s:URL_re . '\zs')
 431
 432    if len(parts) == 0
 433       throw 'ExtractURLCannotFindURL' " No URL found
 434    endif
 435
 436    let length = 0
 437    let column = col('.')
 438
 439    for p in parts
 440       let save_length = length
 441       let length += len(p)
 442       if length >= column
 443          break
 444       endif
 445    endfor
 446
 447    let pos = match(p, s:URL_re)
 448    if pos == -1
 449       throw 'ExtractURLCannotFindURL' " No URL found
 450    endif
 451
 452    if save_length + pos >= column " cursor left of the URL
 453       throw 'ExtractURLCannotFindURL'
 454    endif
 455
 456    return strpart(p, pos)
 457 endfunction
 458
 459 function! EscapeURL(url)
 460    let url = substitute(a:url, ' ', '%20', 'g')
 461    return escape(url, '!#$%')
 462 endfunction
 463
 464 function! OpenURL(url, newwin)
 465    execute "!webbrowser " . a:newwin . " '" . EscapeURL(a:url) . "'"
 466 endfunction
 467
 468 function! ExtractOpenURL(newwin)
 469    try
 470       let url = ExtractURL()
 471    catch /^ExtractURLCannotFindURL$/
 472       echoerr 'No URL found under cursor'
 473       return
 474    endtry
 475
 476    call OpenURL(url, a:newwin)
 477 endfunction
 478
 479 function! EncodeOpenURL(url, newwin)
 480    execute "!webbrowser-encode-url " . a:newwin . " '" . EscapeURL(a:url) . "'"
 481 endfunction
 482
 483
 484 " Send current link to a browser
 485 nmap \b :call ExtractOpenURL('')<CR>
 486 nmap \w :call ExtractOpenURL('-n')<CR>
 487 nmap \t :call ExtractOpenURL('-t')<CR>
 488 " Send visual block to a browser
 489 vmap \b ""y:call OpenURL('<C-R>"', '')<CR>
 490 vmap \w ""y:call OpenURL('<C-R>"', '-n')<CR>
 491 vmap \t ""y:call OpenURL('<C-R>"', '-t')<CR>
 492 " Encode and send visual block to a browser
 493 vmap \B ""y:call EncodeOpenURL('<C-R>"', '')<CR>
 494 vmap \W ""y:call EncodeOpenURL('<C-R>"', '-n')<CR>
 495 vmap \T ""y:call EncodeOpenURL('<C-R>"', '-t')<CR>
 496 " Send current file's name to a browser
 497 nmap \B :call EncodeOpenURL('file:' . expand("%:p"), '')<CR>
 498 nmap \W :call EncodeOpenURL('file:' . expand("%:p"), '-n')<CR>
 499 nmap \T :call EncodeOpenURL('file:' . expand("%:p"), '-t')<CR>
 500
 501 endif " version >= 700
 502
 503
 504 " SPELLING
 505
 506 if has("spell") " Works in 7.0+
 507    " Use builtin spellchecker
 508    nmap \sv :syntax off <BAR> setlocal spell<CR>
 509    " Clear
 510    nmap \sn :syntax on <BAR> setlocal nospell<CR>
 511 endif
 512
 513
 514 " Russian letters mapped in normal mode
 515 "if has("keymap")
 516 "   set keymap=russian-jcuken
 517 "endif
 518
 519 if has("langmap")
 520    if v:version >= 702
 521       " langmap in utf-8 mode requires at least Vim 7.2.109
 522       scriptencoding utf-8
 523       set langmap=ё`Ё~йqцwуeкrеtнyгuшiщoзpх[ъ]фaыsвdаfпgрhоjлkдlж\\;э'
 524                  \яzчxсcмvиbтnьmб\\,ю.ЙQЦWУEКRЕTНYГUШIЩOЗPХ{Ъ}
 525                  \ФAЫSВDАFПGРHОJЛKДLЖ:Э\\"ЯZЧXСCМVИBТNЬMБ<Ю>
 526
 527    elseif &encoding != 'utf-8'
 528       scriptencoding koi8-r
 529       set langmap=ё`Ё~йqцwуeкrеtнyгuшiщoзpх[ъ]фaыsвdаfпgрhоjлkдlж\\;э'
 530                  \яzчxсcмvиbтnьmб\\,ю.ЙQЦWУEКRЕTНYГUШIЩOЗPХ{Ъ}
 531                  \ФAЫSВDАFПGРHОJЛKДLЖ:Э\\"ЯZЧXСCМVИBТNЬMБ<Ю>
 532    endif
 533
 534    scriptencoding us-ascii
 535 endif
 536
 537
 538 if version >= 700
 539 function! W()
 540    " let encodings=filter(split(&fileencodings, ','), 'v:val != "ucs-bom"')
 541    let encodings = ['us-ascii']
 542    if $LC_CTYPE =~ 'UTF-8' " UTF-8 or en_US.UTF-8 or ru_RU.UTF-8 or such
 543       let encodings += ['utf-8']
 544    elseif $LC_CTYPE == 'ru_RU.KOI8-R'
 545       let encodings += ['koi8-r', 'utf-8']
 546    elseif v:lc_time == 'Russian_Russia.1251'
 547       let encodings += ['cp1251', 'utf-8']
 548    endif
 549
 550    for e in encodings
 551       try
 552          execute 'set fileencoding=' . e
 553          w
 554          break
 555       catch /E513: write error, conversion failed/
 556          continue
 557       endtry
 558    endfor
 559
 560    if &modified
 561       throw '"' . expand('%') . '" E513: write error, conversion failed; tried ' . join(encodings, ',')
 562    elseif has("spell")
 563       call SetupSpell()
 564    endif
 565 endfunction
 566
 567 command! W call W()
 568 endif
 569
 570
 571 function! SlowTerm()
 572    set laststatus=1
 573    set noruler
 574    set shortmess=aoOtT
 575    set noshowcmd
 576    set scrolljump=5 " The minimal number of lines to scroll vertically when the cursor gets of the screen
 577    set sidescroll=5
 578    set nottyfast
 579    set notitle
 580    set timeoutlen=5000
 581    set nowildmenu
 582    set wildmode=list:longest
 583    set viminfo=!,h,'10,<100,s5
 584    if has("iconv")
 585       set viminfo+=c
 586    endif
 587    syntax off
 588    highlight NonText cterm=NONE ctermfg=NONE
 589 endfunction
 590
 591 if exists("$SLOWTERM")
 592    call SlowTerm()
 593 endif
 594
 595
 596 if has("python")
 597 pyfile ~/.vim/python/virtualenv.py
 598 endif
 599
 600 if has("python3")
 601 py3file ~/.vim/python/virtualenv.py
 602 endif
 603
 604
 605 " From Tip 212:
 606 " http://vim.fandom.com/wiki/Setting_file_attributes_without_reloading_a_buffer
 607
 608 if executable('chmod')
 609    function! SetExecutableBit(x)
 610       checktime
 611       " Avoid 'Reload Y/N?' question
 612       autocmd FileChangedShell <buffer> call _BufChangedCB()
 613       let fx = executable(expand("%:p"))
 614       if a:x && !fx
 615          silent !chmod a+x %
 616       elseif !a:x && fx
 617          silent !chmod a-x %
 618       endif
 619       if v:shell_error
 620          echoerr 'Error running chmod: ' . v:shell_error
 621       endif
 622       checktime
 623       autocmd! FileChangedShell <buffer>
 624    endfunction
 625    function! _BufChangedCB()
 626       autocmd! FileChangedShell <buffer>
 627    endfunction
 628    command! ToggleXbit if executable(expand("%:p")) | call SetExecutableBit(0) | else | call SetExecutableBit(1) | endif
 629 endif
 630
 631 function! Code()
 632     setlocal expandtab tabstop=8 softtabstop=4 shiftwidth=4
 633 endfunction
 634 command! Code call Code()
 635
 636 function! Text()
 637     setlocal expandtab tabstop=8 softtabstop=3 shiftwidth=3
 638 endfunction
 639 command! Text call Text()
 640
 641 " ----------
 642 " From http://slobin.pp.ru/vim/_vimrc.html
 643
 644 " These options will be kept between editing sessions
 645 " let options = []
 646
 647 " Called automagically after .viminfo and plugins are loaded, sets
 648 " miscellaneous options from persistent global variables
 649 " function! VimEnter()
 650   " for optname in g:options
 651   "   let varname = "g:OPT_" . toupper(optname)
 652   "   if exists(varname)
 653   "     execute "let &" . optname . " = " . varname
 654   "   endif
 655   " endfor
 656
 657   " if has("gui_running") && exists("g:WINPOSX") && exists("g:WINPOSY")
 658   "   execute "winpos" g:WINPOSX g:WINPOSY
 659   " endif
 660 " endfunction
 661
 662 " Called automagically before .viminfo is saved, saves miscellaneous
 663 " options into persistent global variables
 664 " function! VimLeavePre()
 665   " call filter(g:, 'v:key !~# "^OPT_"')
 666   " for optname in g:options
 667   "   let varname = "g:OPT_" . toupper(optname)
 668   "   execute "let " . varname . " = &g:" . optname
 669   " endfor
 670
 671   " if has("gui_running")
 672   "   let g:WINPOSX = getwinposx()
 673   "   let g:WINPOSY = getwinposy()
 674   " endif
 675 " endfunction
 676
 677 " autocmd VimEnter * call VimEnter()
 678 " autocmd VimLeavePre * call VimLeavePre()
 679
 680
 681 " Called automagically after every buffer read, enables fileencoding
 682 " setting from modeline (see Tip #911:
 683 " http://vim.fandom.com/wiki/How_to_make_fileencoding_work_in_the_modeline)
 684 function! AutoEncoding()
 685   if &modified && &fileencoding != ""
 686     call SetupEncoding(&fileencoding)
 687   else
 688     redraw
 689   endif
 690   autocmd! auto-encoding
 691   augroup! auto-encoding
 692 endfunction
 693
 694 augroup auto-encoding
 695 autocmd!
 696 autocmd BufWinEnter * call AutoEncoding()
 697 augroup END
 698
 699
 700 let CONVERT=1
 701
 702 " Value of a character under cursor; better than standard '0x%02B (%b)'
 703 function! HexDec()
 704   let char = matchstr(getline("."), ".", col(".") - 1)
 705   if g:CONVERT
 706     let char = iconv(char, &encoding, &fileencoding)
 707     let format = "0x%02X <%d>"
 708   else
 709     let format = "0x%02X (%d)"
 710   endif
 711   let char = char2nr(char)
 712   return printf(format, char, char)
 713 endfunction
 714
 715
 716 if has("iconv")
 717    " Helper function for :DecodeQP and :DecodeURL commands
 718    function! DecodeHex(arg)
 719      return iconv(printf("%c", str2nr(submatch(1), 16)), a:arg, &encoding)
 720    endfunction
 721
 722    " Custom completion for encoding names
 723    function! EncList(ArgLead, CmdLine, CursorPos)
 724      return filter(split(&fileencodings, ','),
 725                  \ "strpart(v:val, 0, strlen(a:ArgLead)) == a:ArgLead")
 726    endfunction
 727
 728    if version >= 700
 729    " Command for decoding qp-encoded text
 730    command! -bar -nargs=? -range -complete=customlist,EncList DecodeQP
 731           \ <line1>,<line2>s/=\(\x\x\|\n\)/\=DecodeHex(<q-args>)/eg
 732
 733    " Command for decoding url-encoded text
 734    command! -bar -nargs=? -range -complete=customlist,EncList DecodeURL
 735           \ <line1>,<line2>s/%\(\x\x\)/\=DecodeHex(<q-args>)/eg
 736    endif
 737 endif
 738
 739
 740 if has("spell")
 741    function! SetupSpell()
 742       if &fileencoding =~ 'ascii'
 743          setlocal spelllang=en spellfile=~/.vim/spell/en.ascii.add
 744       elseif &fileencoding == 'koi8-r'
 745          setlocal spelllang=en,ru spellfile=~/.vim/spell/en.ascii.add,~/.vim/spell/ru.koi8-r.add
 746       elseif &fileencoding == 'utf-8'
 747          setlocal spelllang=en,ru spellfile=~/.vim/spell/en.ascii.add,~/.vim/spell/ru.utf-8.add
 748       else
 749          setlocal spelllang= spellfile=
 750       endif
 751    endfunction
 752    autocmd BufReadPost * call SetupSpell()
 753 endif
 754
 755
 756 function! SyntaxName()
 757   echomsg synIDattr(synID(line("."), col("."), 1), "name")
 758 endfunction
 759
 760
 761 if has("python")
 762 pyfile ~/.vim/python/completion.py
 763
 764 " Custom completion for python expressions
 765 function! CompList(ArgLead, CmdLine, CursorPos)
 766   python vim_comp_list()
 767 endfunction
 768
 769 " Python command line calculator
 770 command! -nargs=+ -range -complete=customlist,CompList Calc
 771        \ <line1>,<line2> python vim_calc(<q-args>)
 772
 773 " Python text range filter
 774 command! -nargs=+ -range -complete=customlist,CompList Pydo
 775        \ <line1>,<line2> python vim_pydo(<q-args>)
 776
 777 " Display unicode name for the character under cursor
 778 command! Uname python vim_unicode_name()
 779 endif
 780
 781 if has("python3")
 782 py3file ~/.vim/python/completion.py
 783
 784 " Custom completion for python expressions
 785 function! CompList(ArgLead, CmdLine, CursorPos)
 786   python3 vim_comp_list()
 787 endfunction
 788
 789 " Python command line calculator
 790 command! -nargs=+ -range -complete=customlist,CompList Calc
 791        \ <line1>,<line2> python3 vim_calc(<q-args>)
 792
 793 " Python text range filter
 794 command! -nargs=+ -range -complete=customlist,CompList Pydo
 795        \ <line1>,<line2> python3 vim_pydo(<q-args>)
 796
 797 " Display unicode name for the character under cursor
 798 command! Uname python3 vim_unicode_name()
 799 endif
 800
 801 if has("python") || has("python3")
 802 command! UName Uname
 803 endif
 804 " ----------
 805
 806 " This has to go to the very end of ~/.vimrc to allow reading the .vimrc
 807 set secure        " safer working with script files in the current directory