.vimrc

   1 " User configuration file for Vi IMproved.
   2 "
   3 " vim 6.0+ required, 7.0+ recommended.
   4
   5 " 1 important
   6
   7 " Remove ALL autocommands in case the file is sourced for the second time
   8 autocmd!
   9
  10 language messages C " Print messages in English
  11
  12 if exists("b:wrap") " Only do this on the second and subsequent :source's
  13    let fenc = &fileencoding
  14    let ftype = &filetype
  15    let mod = &modified
  16    set all& " Reset all options, except terminal options, to their default value.
  17    execute 'set fileencoding=' . fenc
  18    execute 'set filetype=' . ftype
  19    if mod
  20       set modified
  21    else
  22       set nomodified
  23    endif
  24    unlet fenc ftype mod
  25
  26 elseif filereadable($VIMRUNTIME . "/defaults.vim")
  27    unlet! skip_defaults_vim
  28    source $VIMRUNTIME/defaults.vim
  29 endif
  30
  31 " No, it is not VI, it is VIM! It is important to set this first, because this
  32 " command resets many other options.
  33 set nocompatible
  34
  35 " Set behavior to xterm, not mswin
  36 behave xterm
  37
  38 " 2 moving around, searching and patterns
  39
  40 set ignorecase    " Ignore case in search patterns
  41 set noincsearch   " No incremental searching
  42 set smartcase     " Match 'word' case-insensitive and 'Word' case-sensitive
  43
  44 set nostartofline " Keep cursor's column
  45 set whichwrap=b,s,h,l,<,>,[,],~ " Wrap to the previous/next line on all keys and ~ command
  46
  47 " 4 displaying text
  48
  49 set display=lastline,uhex " Show the last line instead of '@'; show non-printable chars as <hex>
  50 set lazyredraw    " Do not update screen while executing macros
  51 set list          " listchars only works with 'list'
  52 " Show tabs, non-breaking/trailing spaces, long lines
  53 set listchars=tab:>_,nbsp:_,trail:_,extends:+,precedes:+
  54 " Another usefull additions: eol:$,space:_
  55 set scrolloff=0 " number of screen lines to show around the cursor
  56 set wrap          " Visually wrap long lines
  57
  58 " With 'set wrap' wrap long lines at a character in 'breakat'
  59 " Please note 'nolist' is required to use 'linebreak'
  60 set linebreak showbreak=+\ " A plus and a space
  61
  62 set sidescroll=1  " The minimal number of columns to scroll horizontally
  63
  64 " 5 highlighting
  65
  66 colorscheme phd
  67 set nohlsearch    " Stop the search highlighting
  68
  69 " 6 multiple windows
  70
  71 set hidden        " Don't unload a buffer when no longer shown in a window; allow to switch between buffers/windows when the buffer is modified
  72 set laststatus=2  " Always show status line
  73
  74 set splitbelow    " A new window is put below of the current one
  75 set splitright    " A new window is put right of the current one
  76
  77 " 8 terminal
  78
  79 set ttyfast       " terminal connection is fast
  80
  81 set title         " Set title to the value of 'titlestring' or to 'filename - VIM'
  82 set titleold=     " string to restore the title to when exiting Vim
  83 " String to use for the Vim window title; with statusline printf items:
  84 " display filename, modification flag, full path, argument list status,
  85 " the current user, host and program name (to distinguish vim/view/etc).
  86 set titlestring=%t%(\ %M%)%(\ (%{expand(\"%:p:h\")})%)%(\ %a%)\ -\ [%{$USER}@%{hostname()}]\ %{v:progname}
  87
  88 " 9 using the mouse
  89
  90 if has('mouse')
  91    set mouse=ar      " Use mouse in all modes, plus hit-return
  92 endif
  93
  94 " 12 messages and info
  95
  96 set ruler         " Show cursor position below each window
  97 set showcmd       " Show (partial) command keys in the status line
  98
  99 " Short message for [Modified];
 100 " overwrite message for writing a file with subsequent message;
 101 " truncate long file messages
 102 set shortmess=mot
 103
 104 " 14 editing text
 105
 106 set backspace=indent,eol,start
 107 set complete+=k   " Scan spell dictionaries for completion in addition to standard places
 108 set infercase     " adjust case of a keyword completion match
 109 set nojoinspaces  " Do not insert two spaces after a '.', '?' and '!' with a join command
 110 set nrformats=hex " I seldom edit octal numbers, but very often dates like 2001-02-01
 111
 112 " Default value 'croql' is a compromise for both natural and programming
 113 " languages, but as any compromise it works good for neither natural nor
 114 " programming languages. This value is good for natural texts,
 115 " let ftplugins to set values suitable for programming languages.
 116 set formatoptions=2t " list of flags that tell how automatic formatting works
 117
 118 " 15 tabs and indenting
 119
 120 set expandtab     " expand <Tab> to spaces in Insert mode
 121 set shiftwidth=3  " number of spaces used for each step of (auto)indent
 122 set smarttab      " a <Tab> in an indent inserts 'shiftwidth' spaces
 123 set softtabstop=3 " number of spaces to insert for a <Tab>
 124
 125 set noautoindent  " Do not automatically set the indent of a new line
 126
 127 " 18 mapping
 128
 129 set timeout timeoutlen=3000 ttimeoutlen=100 " allow timing out up to 3 seconds halfway into a mapping; 100 ms to wait for a key code or mapped key sequence to complete
 130
 131 " 19 reading and writing files
 132 if v:version >= 703
 133    set cryptmethod=blowfish " encryption method for file writing: zip or blowfish
 134 endif
 135
 136 " 20 the swap file
 137
 138 let myUndoDir = expand('~/tmp/vim/undo')
 139 if !isdirectory(myUndoDir)
 140     " Create dirs
 141     call mkdir(myUndoDir, 'p')
 142 endif
 143
 144 " list of directories for the swap file; remove . (the current directory)
 145 if has("win32")
 146    set directory=~/tmp/vim//,$TEMP//,c:/tmp//,c:/temp//
 147 else
 148    set directory=~/tmp/vim//,~/tmp//,/var/tmp//,/tmp//
 149 endif
 150 " if a directory ends in two path separators "//"
 151 " or "\\", the swap file name will be built from the complete path to
 152 " the file with all path separators substituted to percent '%' signs.
 153 " This will ensure file name uniqueness in the preserve directory.
 154
 155 " 21 command line editing
 156
 157 set history=1000  " how many command lines are remembered
 158 set suffixes+=.pyc,.pyo " list of file name extensions that have a lower priority
 159 set wildignore+=*.py[co] " Ignore these patterns when completing file names
 160 set wildmenu      " command-line completion shows a list of matches
 161 set wildmode=longest,list:longest,full " Bash-vim completion behavior
 162
 163 " Keep undo history across sessions by storing it in a file
 164 if has('persistent_undo')
 165     let &undodir = myUndoDir
 166     set undofile
 167 endif
 168
 169 " 22 executing external commands
 170
 171 if has("filterpipe")
 172    set noshelltemp " Use pipes on Unix
 173 endif
 174
 175 " 25 multi-byte characters
 176
 177 " Automatically detected character encodings
 178 set fileencodings=ucs-bom,us-ascii,utf-8,koi8-r,cp1251,cp866,latin1
 179
 180 " 26 various
 181
 182 " ! - when included, save and restore global variables that start
 183 "     with an uppercase letter, and don't contain a lowercase letter;
 184 " h - disable the effect of 'hlsearch';
 185 " ' - number of files for which the marks are remembered;
 186 " " and < - maximum number of lines saved for a register;
 187 " s - maximum size of an item in Kbytes.
 188 set viminfo=!,h,'50
 189 if version < 603
 190    set viminfo+=\"1000
 191 else
 192    set viminfo+=<1000,s10
 193 endif
 194
 195 " c - convert viminfo to the current encoding;
 196 if has("iconv")
 197    set viminfo+=c
 198 endif
 199
 200 " Removable media paths
 201 if has("win32")
 202    set viminfo+=ra:,rb:
 203 endif
 204
 205 " ----------
 206
 207 if has("gui_running")
 208    set background=light
 209
 210    if has("win32")
 211       "set guifont=Courier_New:h18:cRUSSIAN
 212       set guifont=Lucida_Console:h18:cRUSSIAN
 213    else
 214       set guifont=Monospace\ 16
 215       set toolbar=icons,text " how to show the toolbar
 216    endif
 217
 218    set guicursor+=a:blinkon0 " Stop cursor blinking
 219
 220    " Make shift-insert work like in Xterm
 221    " map <S-Insert> <MiddleMouse>
 222    " map! <S-Insert> <MiddleMouse>
 223
 224    " ----------
 225    " From http://slobin.pp.ru/vim/_vimrc.html
 226
 227    " Arrows should go into wrapped lines, but not while popup menu is visible
 228    imap <expr> <Down> pumvisible() ? "<Down>" : "<C-O>gj"
 229    imap <expr> <Up> pumvisible() ? "<Up>" : "<C-O>gk"
 230
 231    " The <CR> key should select from completion menu without adding a newline
 232    imap <expr> <CR> pumvisible() ? "<C-Y>" : "<CR>"
 233    " ----------
 234
 235 else
 236    if (&term =~ "linux") || ($BACKGROUND == 'DARK') || ($BACKGROUND == 'dark')
 237          \ || has("win32")
 238       " Background of the terminal is black or dark grey
 239       set background=dark
 240    else
 241       set background=light
 242    endif
 243
 244    if (&term =~ "linux")
 245       execute 'set t_kb=' . nr2char(127)
 246    endif
 247
 248    if (&term =~ "rxvt") || (&term =~ "screen") || (&term =~ "term") || (&term =~ "vt100")
 249       execute 'set t_kb=' . nr2char(127)
 250
 251       if has ("terminfo")
 252          " set t_Co=256
 253          set t_Co=16
 254       else
 255          set t_Co=8
 256          set t_Sf="\e[3%dm"
 257          set t_Sb="\e[4%dm"
 258       endif
 259
 260       " 'autoselect' to always put selected text on the clipboard;
 261       " 'unnamed' to use the * register like unnamed register '*'
 262       " for all yank, delete and put operations;
 263       " This allows to use mouse for copy/paste in local xterm,
 264       " but prevents to save the unnamed register between sessions.
 265       " set clipboard=autoselect,unnamed,exclude:cons\|linux
 266
 267       " Use xclip to copy/paste to/from X clipboard at remote host
 268       " vmap "+y :!xclip -i -sel clip
 269       " map "+p :r!xclip -o -sel clip
 270       " Enable X11Forwarding and use ssh -X or even -Y
 271    endif
 272
 273    if (&term =~ "screen")
 274       set ttymouse=xterm2 " Enable mouse codes under screen/tmux
 275       if empty(&t_ts)
 276          " Enable window title under screen/tmux
 277          let &t_ts = "\e]2;"
 278          let &t_fs = "\007"
 279       endif
 280    endif
 281
 282    " Bracketed paste mode
 283    " https://github.com/ConradIrwin/vim-bracketed-paste/blob/master/plugin/bracketed-paste.vim
 284    let &t_ti .= "\<Esc>[?2004h"
 285    let &t_te = "\e[?2004l" . &t_te
 286
 287    function! XTermPasteBegin(ret)
 288      set pastetoggle=<f29>
 289      set paste
 290      return a:ret
 291    endfunction
 292
 293    execute "set <f28>=\<Esc>[200~"
 294    execute "set <f29>=\<Esc>[201~"
 295    map <expr> <f28> XTermPasteBegin("i")
 296    imap <expr> <f28> XTermPasteBegin("")
 297    vmap <expr> <f28> XTermPasteBegin("c")
 298    cmap <f28> <nop>
 299    cmap <f29> <nop>
 300 endif
 301
 302 " Multiline comments often confuse vim syntax highlighting - these maps
 303 " allow to resynchronize; the first is faster, the second is more thorough
 304 nmap \sc :syntax sync clear<Enter>
 305 nmap \ss :syntax sync fromstart<Enter>
 306
 307
 308 " AUTOCOMMANDS
 309
 310 " Enable filetype detection
 311 filetype plugin indent on
 312
 313 runtime macros/matchit.vim
 314
 315 " Reread me after editing
 316 autocmd BufWritePost ~/.vimrc source ~/.vimrc | syntax on
 317
 318 if version >= 700
 319 " Save all files before running any quickfix command (grep, makeprg, etc.)
 320 autocmd QuickFixCmdPre * wall
 321 " automatically close quickfix if it's the only window left
 322 autocmd WinEnter * if winnr('$') == 1 &&
 323    \ index(["nofile", "quickfix"], &buftype) >= 0 | quit | endif
 324 endif
 325
 326 " Syntax highlighting
 327 autocmd BufReadPost * syntax on
 328
 329
 330 " Restore last known cursor position
 331 function! RestorePosition()
 332    if exists('b:position_restored')
 333       return
 334    endif
 335
 336    if line("'\"") > 0
 337       call cursor(line("'\""), col("'\""))
 338    endif
 339    let b:position_restored = 1
 340 endfunction
 341
 342 " When editing a file, always jump to the last cursor position (if saved)
 343 autocmd BufReadPost * call RestorePosition()
 344
 345
 346 function! SetupEncoding(encoding)
 347    if !has("iconv") || exists('b:encoding_set') || strlen(a:encoding) == 0
 348       return
 349    endif
 350
 351    call RestorePosition()
 352    let b:encoding_set = 1
 353    if len(expand('%'))
 354       execute "edit ++enc=" . a:encoding
 355    endif
 356 endfunction
 357
 358
 359 " From http://lwn.net/Articles/226514/
 360
 361 augroup gpg
 362 " Remove ALL autocommands for the current group.
 363 autocmd!
 364 autocmd BufReadPre,FileReadPre *.gpg set viminfo=
 365 autocmd BufReadPre,FileReadPre *.gpg setlocal noswapfile
 366 autocmd BufReadPost *.gpg :%!gpg -q -d
 367 autocmd BufReadPost *.gpg | redraw
 368 autocmd BufWritePre *.gpg :%!gpg --default-recipient-self -q -e -a
 369 autocmd BufWritePost *.gpg u
 370 autocmd VimLeave *.gpg :!clear
 371 " For OpenSSL:
 372 " BufReadPost: use "openssl bf -d -a"
 373 " BufWritePre: use "openssl bf -salt -a"
 374 augroup END
 375
 376
 377 function! SetWrap()
 378    setlocal wrap
 379    map <Up> gk
 380    imap <Up> <C-O>gk
 381    map <Down> gj
 382    imap <Down> <C-O>gj
 383    let b:wrap = 1
 384 endfunction
 385
 386 function! SetNoWrap()
 387    setlocal nowrap
 388    map <Up> k
 389    map <Down> j
 390    let b:wrap = 0
 391 endfunction
 392
 393 command! SetWrap call SetWrap()
 394 command! SetNoWrap call SetNoWrap()
 395
 396 " b:wrap can be set by an ftplugin
 397 autocmd BufReadPost * if !exists("b:wrap") | call SetWrap() | endif
 398
 399
 400 " MAPPINGS
 401
 402 " Do not unindent #-comment
 403 inoremap # X<C-H>#
 404
 405 " map <C-A> <Home>
 406 " map <C-E> <End>
 407 " map <C-Z> :shell<CR>
 408
 409
 410 if version >= 700
 411 " WEB BROWSERS
 412
 413 let s:URL_re="\\v(((https?|ftp|gopher|telnet)://|(mailto|file|news|about|ed2k|irc|sip|magnet):)[^' \t<>\"]+|(www|web|w3)[a-z0-9_-]*\\.[a-z0-9._-]+\\.[^' \t<>\"]+)[a-z0-9/]\\c"
 414
 415 function! ExtractURL()
 416    let line = getline('.')
 417    let parts = split(line, s:URL_re . '\zs')
 418
 419    if len(parts) == 0
 420       throw 'ExtractURLCannotFindURL' " No URL found
 421    endif
 422
 423    let length = 0
 424    let column = col('.')
 425
 426    for p in parts
 427       let save_length = length
 428       let length += len(p)
 429       if length >= column
 430          break
 431       endif
 432    endfor
 433
 434    let pos = match(p, s:URL_re)
 435    if pos == -1
 436       throw 'ExtractURLCannotFindURL' " No URL found
 437    endif
 438
 439    if save_length + pos >= column " cursor left of the URL
 440       throw 'ExtractURLCannotFindURL'
 441    endif
 442
 443    return strpart(p, pos)
 444 endfunction
 445
 446 function! EscapeURL(url)
 447    let url = substitute(a:url, ' ', '%20', 'g')
 448    return escape(url, '!#$%')
 449 endfunction
 450
 451 function! OpenURL(url, newwin)
 452    execute "!webbrowser " . a:newwin . " '" . EscapeURL(a:url) . "'"
 453 endfunction
 454
 455 function! ExtractOpenURL(newwin)
 456    try
 457       let url = ExtractURL()
 458    catch /^ExtractURLCannotFindURL$/
 459       echoerr 'No URL found under cursor'
 460       return
 461    endtry
 462
 463    call OpenURL(url, a:newwin)
 464 endfunction
 465
 466 function! EncodeOpenURL(url, newwin)
 467    execute "!webbrowser-encode-url " . a:newwin . " '" . EscapeURL(a:url) . "'"
 468 endfunction
 469
 470
 471 " Send current link to a browser
 472 nmap \b :call ExtractOpenURL('')<CR>
 473 nmap \w :call ExtractOpenURL('-n')<CR>
 474 nmap \t :call ExtractOpenURL('-t')<CR>
 475 " Send visual block to a browser
 476 vmap \b ""y:call OpenURL('<C-R>"', '')<CR>
 477 vmap \w ""y:call OpenURL('<C-R>"', '-n')<CR>
 478 vmap \t ""y:call OpenURL('<C-R>"', '-t')<CR>
 479 " Encode and send visual block to a browser
 480 vmap \B ""y:call EncodeOpenURL('<C-R>"', '')<CR>
 481 vmap \W ""y:call EncodeOpenURL('<C-R>"', '-n')<CR>
 482 vmap \T ""y:call EncodeOpenURL('<C-R>"', '-t')<CR>
 483 " Send current file's name to a browser
 484 nmap \B :call EncodeOpenURL('file:' . expand("%:p"), '')<CR>
 485 nmap \W :call EncodeOpenURL('file:' . expand("%:p"), '-n')<CR>
 486 nmap \T :call EncodeOpenURL('file:' . expand("%:p"), '-t')<CR>
 487
 488 endif " version >= 700
 489
 490
 491 " SPELLING
 492
 493 if has("spell") " Works in 7.0+
 494    " Use builtin spellchecker
 495    nmap \sv :syntax off <BAR> setlocal spell<CR>
 496    " Clear
 497    nmap \sn :syntax on <BAR> setlocal nospell<CR>
 498 endif
 499
 500
 501 " Russian letters mapped in normal mode
 502 "if has("keymap")
 503 "   set keymap=russian-jcuken
 504 "endif
 505
 506 if has("langmap")
 507    if v:version >= 702
 508       " langmap in utf-8 mode requires at least Vim 7.2.109
 509       scriptencoding utf-8
 510       set langmap=ё`Ё~йqцwуeкrеtнyгuшiщoзpх[ъ]фaыsвdаfпgрhоjлkдlж\\;э'
 511                  \яzчxсcмvиbтnьmб\\,ю.ЙQЦWУEКRЕTНYГUШIЩOЗPХ{Ъ}
 512                  \ФAЫSВDАFПGРHОJЛKДLЖ:Э\\"ЯZЧXСCМVИBТNЬMБ<Ю>
 513
 514    elseif &encoding != 'utf-8'
 515       scriptencoding koi8-r
 516       set langmap=ё`Ё~йqцwуeкrеtнyгuшiщoзpх[ъ]фaыsвdаfпgрhоjлkдlж\\;э'
 517                  \яzчxсcмvиbтnьmб\\,ю.ЙQЦWУEКRЕTНYГUШIЩOЗPХ{Ъ}
 518                  \ФAЫSВDАFПGРHОJЛKДLЖ:Э\\"ЯZЧXСCМVИBТNЬMБ<Ю>
 519    endif
 520
 521    scriptencoding us-ascii
 522 endif
 523
 524
 525 if version >= 700
 526 function! W()
 527    " let encodings=filter(split(&fileencodings, ','), 'v:val != "ucs-bom"')
 528    let encodings = ['us-ascii']
 529    if $LC_CTYPE =~ 'UTF-8' " UTF-8 or en_US.UTF-8 or ru_RU.UTF-8 or such
 530       let encodings += ['utf-8']
 531    elseif $LC_CTYPE == 'ru_RU.KOI8-R'
 532       let encodings += ['koi8-r', 'utf-8']
 533    elseif v:lc_time == 'Russian_Russia.1251'
 534       let encodings += ['cp1251', 'utf-8']
 535    endif
 536
 537    for e in encodings
 538       try
 539          execute 'set fileencoding=' . e
 540          w
 541          break
 542       catch /E513: write error, conversion failed/
 543          continue
 544       endtry
 545    endfor
 546
 547    if &modified
 548       throw '"' . expand('%') . '" E513: write error, conversion failed; tried ' . join(encodings, ',')
 549    elseif has("spell")
 550       call SetupSpell()
 551    endif
 552 endfunction
 553
 554 command! W call W()
 555 endif
 556
 557
 558 function! SlowTerm()
 559    set laststatus=1
 560    set noruler
 561    set shortmess=aoOtT
 562    set noshowcmd
 563    set scrolljump=5 " The minimal number of lines to scroll vertically when the cursor gets of the screen
 564    set sidescroll=5
 565    set nottyfast
 566    set notitle
 567    set timeoutlen=5000
 568    set nowildmenu
 569    set wildmode=list:longest
 570    set viminfo=!,h,'10,<100,s5
 571    if has("iconv")
 572       set viminfo+=c
 573    endif
 574    syntax off
 575    highlight NonText cterm=NONE ctermfg=NONE
 576 endfunction
 577
 578 if exists("$SLOWTERM")
 579    call SlowTerm()
 580 endif
 581
 582
 583 if has("python")
 584 pyfile ~/.vim/python/virtualenv.py
 585 endif
 586
 587 if has("python3")
 588 py3file ~/.vim/python/virtualenv.py
 589 endif
 590
 591
 592 " From Tip 212:
 593 " http://vim.fandom.com/wiki/Setting_file_attributes_without_reloading_a_buffer
 594
 595 if executable('chmod')
 596    function! SetExecutableBit(x)
 597       checktime
 598       " Avoid 'Reload Y/N?' question
 599       autocmd FileChangedShell <buffer> call _BufChangedCB()
 600       let fx = executable(expand("%:p"))
 601       if a:x && !fx
 602          silent !chmod a+x %
 603       elseif !a:x && fx
 604          silent !chmod a-x %
 605       endif
 606       if v:shell_error
 607          echoerr 'Error running chmod: ' . v:shell_error
 608       endif
 609       checktime
 610       autocmd! FileChangedShell <buffer>
 611    endfunction
 612    function! _BufChangedCB()
 613       autocmd! FileChangedShell <buffer>
 614    endfunction
 615    command! ToggleXbit if executable(expand("%:p")) | call SetExecutableBit(0) | else | call SetExecutableBit(1) | endif
 616 endif
 617
 618 function! Code()
 619     setlocal expandtab tabstop=8 softtabstop=4 shiftwidth=4
 620 endfunction
 621 command! Code call Code()
 622
 623 function! Text()
 624     setlocal expandtab tabstop=8 softtabstop=3 shiftwidth=3
 625 endfunction
 626 command! Text call Text()
 627
 628 " ----------
 629 " From http://slobin.pp.ru/vim/_vimrc.html
 630
 631 " These options will be kept between editing sessions
 632 " let options = []
 633
 634 " Called automagically after .viminfo and plugins are loaded, sets
 635 " miscellaneous options from persistent global variables
 636 " function! VimEnter()
 637   " for optname in g:options
 638   "   let varname = "g:OPT_" . toupper(optname)
 639   "   if exists(varname)
 640   "     execute "let &" . optname . " = " . varname
 641   "   endif
 642   " endfor
 643
 644   " if has("gui_running") && exists("g:WINPOSX") && exists("g:WINPOSY")
 645   "   execute "winpos" g:WINPOSX g:WINPOSY
 646   " endif
 647 " endfunction
 648
 649 " Called automagically before .viminfo is saved, saves miscellaneous
 650 " options into persistent global variables
 651 " function! VimLeavePre()
 652   " call filter(g:, 'v:key !~# "^OPT_"')
 653   " for optname in g:options
 654   "   let varname = "g:OPT_" . toupper(optname)
 655   "   execute "let " . varname . " = &g:" . optname
 656   " endfor
 657
 658   " if has("gui_running")
 659   "   let g:WINPOSX = getwinposx()
 660   "   let g:WINPOSY = getwinposy()
 661   " endif
 662 " endfunction
 663
 664 " autocmd VimEnter * call VimEnter()
 665 " autocmd VimLeavePre * call VimLeavePre()
 666
 667
 668 " Called automagically after every buffer read, enables fileencoding
 669 " setting from modeline (see Tip #911:
 670 " http://vim.fandom.com/wiki/How_to_make_fileencoding_work_in_the_modeline)
 671 function! AutoEncoding()
 672   if &modified && &fileencoding != ""
 673     call SetupEncoding(&fileencoding)
 674   else
 675     redraw
 676   endif
 677   autocmd! auto-encoding
 678   augroup! auto-encoding
 679 endfunction
 680
 681 augroup auto-encoding
 682 autocmd!
 683 autocmd BufWinEnter * call AutoEncoding()
 684 augroup END
 685
 686
 687 let CONVERT=1
 688
 689 " Value of a character under cursor; better than standard '0x%02B (%b)'
 690 function! HexDec()
 691   let char = matchstr(getline("."), ".", col(".") - 1)
 692   if g:CONVERT
 693     let char = iconv(char, &encoding, &fileencoding)
 694     let format = "0x%02X <%d>"
 695   else
 696     let format = "0x%02X (%d)"
 697   endif
 698   let char = char2nr(char)
 699   return printf(format, char, char)
 700 endfunction
 701
 702
 703 if has("iconv")
 704    " Helper function for :DecodeQP and :DecodeURL commands
 705    function! DecodeHex(arg)
 706      return iconv(printf("%c", str2nr(submatch(1), 16)), a:arg, &encoding)
 707    endfunction
 708
 709    " Custom completion for encoding names
 710    function! EncList(ArgLead, CmdLine, CursorPos)
 711      return filter(split(&fileencodings, ','),
 712                  \ "strpart(v:val, 0, strlen(a:ArgLead)) == a:ArgLead")
 713    endfunction
 714
 715    if version >= 700
 716    " Command for decoding qp-encoded text
 717    command! -bar -nargs=? -range -complete=customlist,EncList DecodeQP
 718           \ <line1>,<line2>s/=\(\x\x\|\n\)/\=DecodeHex(<q-args>)/eg
 719
 720    " Command for decoding url-encoded text
 721    command! -bar -nargs=? -range -complete=customlist,EncList DecodeURL
 722           \ <line1>,<line2>s/%\(\x\x\)/\=DecodeHex(<q-args>)/eg
 723    endif
 724 endif
 725
 726
 727 if has("spell")
 728    function! SetupSpell()
 729       if &fileencoding =~ 'ascii'
 730          setlocal spelllang=en spellfile=~/.vim/spell/en.ascii.add
 731       elseif &fileencoding == 'koi8-r'
 732          setlocal spelllang=en,ru spellfile=~/.vim/spell/en.ascii.add,~/.vim/spell/ru.koi8-r.add
 733       elseif &fileencoding == 'utf-8'
 734          setlocal spelllang=en,ru spellfile=~/.vim/spell/en.ascii.add,~/.vim/spell/ru.utf-8.add
 735       else
 736          setlocal spelllang= spellfile=
 737       endif
 738    endfunction
 739    autocmd BufReadPost * call SetupSpell()
 740 endif
 741
 742
 743 function! SyntaxName()
 744   echomsg synIDattr(synID(line("."), col("."), 1), "name")
 745 endfunction
 746
 747
 748 if has("python")
 749 pyfile ~/.vim/python/completion.py
 750
 751 " Custom completion for python expressions
 752 function! CompList(ArgLead, CmdLine, CursorPos)
 753   python vim_comp_list()
 754 endfunction
 755
 756 " Python command line calculator
 757 command! -nargs=+ -range -complete=customlist,CompList Calc
 758        \ <line1>,<line2> python vim_calc(<q-args>)
 759
 760 " Python text range filter
 761 command! -nargs=+ -range -complete=customlist,CompList Pydo
 762        \ <line1>,<line2> python vim_pydo(<q-args>)
 763
 764 " Display unicode name for the character under cursor
 765 command! Uname python vim_unicode_name()
 766 endif
 767
 768 if has("python3")
 769 py3file ~/.vim/python/completion.py
 770
 771 " Custom completion for python expressions
 772 function! CompList(ArgLead, CmdLine, CursorPos)
 773   python3 vim_comp_list()
 774 endfunction
 775
 776 " Python command line calculator
 777 command! -nargs=+ -range -complete=customlist,CompList Calc
 778        \ <line1>,<line2> python3 vim_calc(<q-args>)
 779
 780 " Python text range filter
 781 command! -nargs=+ -range -complete=customlist,CompList Pydo
 782        \ <line1>,<line2> python3 vim_pydo(<q-args>)
 783
 784 " Display unicode name for the character under cursor
 785 command! Uname python3 vim_unicode_name()
 786 endif
 787
 788 if has("python") || has("python3")
 789 command! UName Uname
 790 endif
 791 " ----------
 792
 793 " This has to go to the very end of ~/.vimrc to allow reading the .vimrc
 794 set secure        " safer working with script files in the current directory