.vimrc

   1 " User configuration file for Vi IMproved.
   2 "
   3 " vim 6.0+ required, 7.0+ recommended.
   4
   5 " 1 important
   6
   7 " Remove ALL autocommands in case the file is sourced for the second time
   8 autocmd!
   9
  10 language messages C " Print messages in English
  11
  12 if exists("b:wrap") " Only do this on the second and subsequent :source's
  13    let fenc = &fileencoding
  14    let ftype = &filetype
  15    let mod = &modified
  16    set all& " Reset all options, except terminal options, to their default value.
  17    execute 'set fileencoding=' . fenc
  18    execute 'set filetype=' . ftype
  19    if mod
  20       set modified
  21    else
  22       set nomodified
  23    endif
  24    unlet fenc ftype mod
  25 endif
  26
  27 " No, it is not VI, it is VIM! It is important to set this first, because this
  28 " command resets many other options.
  29 set nocompatible
  30
  31 " Set behavior to xterm, not mswin
  32 behave xterm
  33
  34 " 2 moving around, searching and patterns
  35
  36 set ignorecase    " Ignore case in search patterns
  37 set smartcase     " Match 'word' case-insensitive and 'Word' case-sensitive
  38
  39 set nostartofline " Keep cursor's column
  40 set whichwrap=b,s,h,l,<,>,[,],~ " Wrap to the previous/next line on all keys and ~ command
  41
  42 " 4 displaying text
  43
  44 set display=lastline,uhex " Show the last line instead of '@'; show non-printable chars as <hex>
  45 set lazyredraw    " Do not update screen while executing macros
  46 set list          " listchars only works with 'list'
  47 set listchars=tab:>_,trail:_,extends:+ " Show tabs, trailing spaces, long lines
  48 set wrap          " Visually wrap long lines
  49
  50 " With 'set wrap' wrap long lines at a character in 'breakat'
  51 " Please note 'nolist' is required to use 'linebreak'
  52 set linebreak showbreak=+\ " A plus and a space
  53
  54 set sidescroll=1  " The minimal number of columns to scroll horizontally
  55
  56 " 5 highlighting
  57
  58 colorscheme phd
  59 set nohlsearch    " Stop the search highlighting
  60
  61 " 6 multiple windows
  62
  63 set hidden        " Don't unload a buffer when no longer shown in a window; allow to switch between buffers/windows when the buffer is modified
  64 set laststatus=2  " Always show status line
  65
  66 set splitbelow    " A new window is put below of the current one
  67 set splitright    " A new window is put right of the current one
  68
  69 " 8 terminal
  70
  71 set ttyfast       " terminal connection is fast
  72
  73 set title         " Set title to the value of 'titlestring' or to 'filename - VIM'
  74 set titleold=     " string to restore the title to when exiting Vim
  75 " String to use for the Vim window title; with statusline printf items:
  76 " display filename, modification flag, full path, argument list status,
  77 " the current user, host and program name (to distinguish vim/view/etc).
  78 set titlestring=%t%(\ %M%)%(\ (%{expand(\"%:p:h\")})%)%(\ %a%)\ -\ [%{$USER}@%{hostname()}]\ %{v:progname}
  79
  80 " 9 using the mouse
  81
  82 set mouse=ar      " Use mouse in all modes, plus hit-return
  83
  84 " 12 messages and info
  85
  86 set ruler         " Show cursor position below each window
  87 set showcmd       " Show (partial) command keys in the status line
  88
  89 " Short message for [Modified];
  90 " overwrite message for writing a file with subsequent message;
  91 " truncate long file messages
  92 set shortmess=mot
  93
  94 " 14 editing text
  95
  96 set backspace=indent,eol,start
  97 set complete+=k   " Scan spell dictionaries for completion in addition to standard places
  98 set infercase     " adjust case of a keyword completion match
  99 set nojoinspaces  " Do not insert two spaces after a '.', '?' and '!' with a join command
 100 set nrformats=hex " I seldom edit octal numbers, but very often dates like 2001-02-01
 101
 102 " Default value 'croql' is a compromise for both natural and programming
 103 " languages, but as any compromise it works good for neither natural nor
 104 " programming languages. This value is good for natural texts,
 105 " let ftplugins to set values suitable for programming languages.
 106 set formatoptions=2t " list of flags that tell how automatic formatting works
 107
 108 " 15 tabs and indenting
 109
 110 set expandtab     " expand <Tab> to spaces in Insert mode
 111 set shiftwidth=3  " number of spaces used for each step of (auto)indent
 112 set smarttab      " a <Tab> in an indent inserts 'shiftwidth' spaces
 113 set softtabstop=3 " number of spaces to insert for a <Tab>
 114
 115 set noautoindent  " Do not automatically set the indent of a new line
 116
 117 " 18 mapping
 118
 119 set timeout timeoutlen=3000 ttimeoutlen=100 " allow timing out up to 3 seconds halfway into a mapping; 100 ms to wait for a key code or mapped key sequence to complete
 120
 121 " 19 reading and writing files
 122 if v:version >= 703
 123    set cryptmethod=blowfish " encryption method for file writing: zip or blowfish
 124 endif
 125
 126 " 20 the swap file
 127
 128 let myUndoDir = expand('~/tmp/vim/undo')
 129 if !isdirectory(myUndoDir)
 130     " Create dirs
 131     call mkdir(myUndoDir, 'p')
 132 endif
 133
 134 " list of directories for the swap file; remove . (the current directory)
 135 if has("win32")
 136    set directory=~/tmp/vim//,$TEMP//,c:/tmp//,c:/temp//
 137 else
 138    set directory=~/tmp/vim//,~/tmp//,/var/tmp//,/tmp//
 139 endif
 140 " if a directory ends in two path separators "//"
 141 " or "\\", the swap file name will be built from the complete path to
 142 " the file with all path separators substituted to percent '%' signs.
 143 " This will ensure file name uniqueness in the preserve directory.
 144
 145 " 21 command line editing
 146
 147 set history=1000  " how many command lines are remembered
 148 set suffixes+=.pyc,.pyo " list of file name extensions that have a lower priority
 149 set wildignore+=*.py[co] " Ignore these patterns when completing file names
 150 set wildmenu      " command-line completion shows a list of matches
 151 set wildmode=longest,list:longest,full " Bash-vim completion behavior
 152
 153 " Keep undo history across sessions by storing it in a file
 154 if has('persistent_undo')
 155     let &undodir = myUndoDir
 156     set undofile
 157 endif
 158
 159 " 22 executing external commands
 160
 161 if has("filterpipe")
 162    set noshelltemp " Use pipes on Unix
 163 endif
 164
 165 " 25 multi-byte characters
 166
 167 " Automatically detected character encodings
 168 set fileencodings=ucs-bom,us-ascii,utf-8,koi8-r,cp1251,cp866,latin1
 169
 170 " 26 various
 171
 172 " ! - when included, save and restore global variables that start
 173 "     with an uppercase letter, and don't contain a lowercase letter;
 174 " h - disable the effect of 'hlsearch';
 175 " ' - number of files for which the marks are remembered;
 176 " " and < - maximum number of lines saved for a register;
 177 " s - maximum size of an item in Kbytes.
 178 if version < 603
 179    set viminfo=!,h,'50,\"1000
 180 else
 181    set viminfo=!,h,'50,<1000,s10
 182 endif
 183
 184 " c - convert viminfo to the current encoding;
 185 if has("iconv")
 186    set viminfo^=c
 187 endif
 188
 189 " Removable media paths
 190 if has("win32")
 191    set viminfo+=ra:,rb:
 192 endif
 193
 194 " ----------
 195
 196 if has("gui_running")
 197    set background=light
 198
 199    if has("win32")
 200       "set guifont=Courier_New:h18:cRUSSIAN
 201       set guifont=Lucida_Console:h18:cRUSSIAN
 202    else
 203       set guifont=Monospace\ 16
 204       set toolbar=icons,text " how to show the toolbar
 205    endif
 206
 207    set guicursor+=a:blinkon0 " Stop cursor blinking
 208
 209    " Make shift-insert work like in Xterm
 210    " map <S-Insert> <MiddleMouse>
 211    " map! <S-Insert> <MiddleMouse>
 212
 213    " ----------
 214    " From http://slobin.pp.ru/vim/_vimrc.html
 215
 216    " Arrows should go into wrapped lines, but not while popup menu is visible
 217    imap <expr> <Down> pumvisible() ? "<Down>" : "<C-O>gj"
 218    imap <expr> <Up> pumvisible() ? "<Up>" : "<C-O>gk"
 219
 220    " The <CR> key should select from completion menu without adding a newline
 221    imap <expr> <CR> pumvisible() ? "<C-Y>" : "<CR>"
 222    " ----------
 223
 224 else
 225    if (&term =~ "linux") || ($BACKGROUND == 'DARK') || ($BACKGROUND == 'dark')
 226          \ || has("win32")
 227       " Background of the terminal is black or dark grey
 228       set background=dark
 229    else
 230       set background=light
 231    endif
 232
 233    if (&term =~ "linux")
 234       execute 'set t_kb=' . nr2char(127)
 235    endif
 236
 237    if (&term =~ "rxvt") || (&term =~ "screen") || (&term =~ "term") || (&term =~ "vt100")
 238       execute 'set t_kb=' . nr2char(127)
 239
 240       if has ("terminfo")
 241          " set t_Co=256
 242          set t_Co=16
 243       else
 244          set t_Co=8
 245          set t_Sf="\e[3%dm"
 246          set t_Sb="\e[4%dm"
 247       endif
 248
 249       " 'autoselect' to always put selected text on the clipboard;
 250       " 'unnamed' to use the * register like unnamed register '*'
 251       " for all yank, delete and put operations;
 252       " This allows to use mouse for copy/paste in local xterm,
 253       " but prevents to save the unnamed register between sessions.
 254       " set clipboard=autoselect,unnamed,exclude:cons\|linux
 255
 256       " Use xclip to copy/paste to/from X clipboard at remote host
 257       " vmap "+y :!xclip -i -sel clip
 258       " map "+p :r!xclip -o -sel clip
 259       " Enable X11Forwarding and use ssh -X or even -Y
 260    endif
 261
 262    if (&term =~ "screen")
 263       set ttymouse=xterm2 " Enable mouse codes under screen/tmux
 264       if empty(&t_ts)
 265          " Enable window title under screen/tmux
 266          let &t_ts = "\e]2;"
 267          let &t_fs = "\007"
 268       endif
 269    endif
 270
 271    " Automatically set paste mode in Vim when pasting in bracketed paste mode
 272    " https://coderwall.com/p/if9mda/automatically-set-paste-mode-in-vim-when-pasting-in-insert-mode
 273    function! WrapForTmux(s)
 274      if !exists('$TMUX')
 275        return a:s
 276      endif
 277
 278      let tmux_start = "\<Esc>Ptmux;"
 279      let tmux_end = "\<Esc>\\"
 280
 281      return tmux_start . substitute(a:s, "\<Esc>", "\<Esc>\<Esc>", 'g') . tmux_end
 282    endfunction
 283
 284    let &t_SI .= WrapForTmux("\<Esc>[?2004h")
 285    let &t_EI .= WrapForTmux("\<Esc>[?2004l")
 286
 287    function! XTermPasteBegin()
 288      set pastetoggle=<Esc>[201~
 289      set paste
 290      return ""
 291    endfunction
 292
 293    inoremap <special> <expr> <Esc>[200~ XTermPasteBegin()
 294 endif
 295
 296 " Multiline comments often confuse vim syntax highlighting - these maps
 297 " allow to resynchronize; the first is faster, the second is more thorough
 298 nmap \sc :syntax sync clear<Enter>
 299 nmap \ss :syntax sync fromstart<Enter>
 300
 301
 302 " AUTOCOMMANDS
 303
 304 " Enable filetype detection
 305 filetype plugin indent on
 306
 307 runtime macros/matchit.vim
 308
 309 " Reread me after editing
 310 autocmd BufWritePost ~/.vimrc source ~/.vimrc | syntax on
 311
 312 if version >= 700
 313 " Save all files before running any quickfix command (grep, makeprg, etc.)
 314 autocmd QuickFixCmdPre * wall
 315 " automatically close quickfix if it's the only window left
 316 autocmd WinEnter * if winnr('$') == 1 && &buftype == "quickfix" | quit | endif
 317 endif
 318
 319 " Syntax highlighting
 320 autocmd BufReadPost * syntax on
 321
 322
 323 " Restore last known cursor position
 324 function! RestorePosition()
 325    if exists('b:position_restored')
 326       return
 327    endif
 328
 329    if line("'\"") > 0
 330       call cursor(line("'\""), col("'\""))
 331    endif
 332    let b:position_restored = 1
 333 endfunction
 334
 335 " When editing a file, always jump to the last cursor position (if saved)
 336 autocmd BufReadPost * call RestorePosition()
 337
 338
 339 function! SetupEncoding(encoding)
 340    if !has("iconv") || exists('b:encoding_set') || strlen(a:encoding) == 0
 341       return
 342    endif
 343
 344    call RestorePosition()
 345    let b:encoding_set = 1
 346    execute "edit ++enc=" . a:encoding
 347 endfunction
 348
 349
 350 " From http://lwn.net/Articles/226514/
 351
 352 augroup gpg
 353 " Remove ALL autocommands for the current group.
 354 autocmd!
 355 autocmd BufReadPre,FileReadPre *.gpg set viminfo=
 356 autocmd BufReadPre,FileReadPre *.gpg setlocal noswapfile
 357 autocmd BufReadPost *.gpg :%!gpg -q -d
 358 autocmd BufReadPost *.gpg | redraw
 359 autocmd BufWritePre *.gpg :%!gpg --default-recipient-self -q -e -a
 360 autocmd BufWritePost *.gpg u
 361 autocmd VimLeave *.gpg :!clear
 362 " For OpenSSL:
 363 " BufReadPost: use "openssl bf -d -a"
 364 " BufWritePre: use "openssl bf -salt -a"
 365 augroup END
 366
 367
 368 function! SetWrap()
 369    setlocal wrap
 370    map <Up> gk
 371    imap <Up> <C-O>gk
 372    map <Down> gj
 373    imap <Down> <C-O>gj
 374    let b:wrap = 1
 375 endfunction
 376
 377 function! SetNoWrap()
 378    setlocal nowrap
 379    map <Up> k
 380    map <Down> j
 381    let b:wrap = 0
 382 endfunction
 383
 384 command! SetWrap call SetWrap()
 385 command! SetNoWrap call SetNoWrap()
 386
 387 " b:wrap can be set by an ftplugin
 388 autocmd BufReadPost * if !exists("b:wrap") | call SetWrap() | endif
 389
 390
 391 " MAPPINGS
 392
 393 " Do not unindent #-comment
 394 inoremap # X<C-H>#
 395
 396 " map <C-A> <Home>
 397 " map <C-E> <End>
 398 " map <C-Z> :shell<CR>
 399
 400
 401 if version >= 700
 402 " WEB BROWSERS
 403
 404 let s:URL_re="\\v(((https?|ftp|gopher|telnet)://|(mailto|file|news|about|ed2k|irc|sip|magnet):)[^' \t<>\"]+|(www|web|w3)[a-z0-9_-]*\\.[a-z0-9._-]+\\.[^' \t<>\"]+)[a-z0-9/]\\c"
 405
 406 function! ExtractURL()
 407    let line = getline('.')
 408    let parts = split(line, s:URL_re . '\zs')
 409
 410    if len(parts) == 0
 411       throw 'ExtractURLCannotFindURL' " No URL found
 412    endif
 413
 414    let length = 0
 415    let column = col('.')
 416
 417    for p in parts
 418       let save_length = length
 419       let length += len(p)
 420       if length >= column
 421          break
 422       endif
 423    endfor
 424
 425    let pos = match(p, s:URL_re)
 426    if pos == -1
 427       throw 'ExtractURLCannotFindURL' " No URL found
 428    endif
 429
 430    if save_length + pos >= column " cursor left of the URL
 431       throw 'ExtractURLCannotFindURL'
 432    endif
 433
 434    return strpart(p, pos)
 435 endfunction
 436
 437 function! EscapeURL(url)
 438    let url = substitute(a:url, ' ', '%20', 'g')
 439    return escape(url, '!#$%')
 440 endfunction
 441
 442 function! OpenURL(url, newwin)
 443    execute "!webbrowser " . a:newwin . " '" . EscapeURL(a:url) . "'"
 444 endfunction
 445
 446 function! ExtractOpenURL(newwin)
 447    try
 448       let url = ExtractURL()
 449    catch /^ExtractURLCannotFindURL$/
 450       echoerr 'No URL found under cursor'
 451       return
 452    endtry
 453
 454    call OpenURL(url, a:newwin)
 455 endfunction
 456
 457 function! EncodeOpenURL(url, newwin)
 458    execute "!webbrowser-encode-url " . a:newwin . " '" . EscapeURL(a:url) . "'"
 459 endfunction
 460
 461
 462 " Send current link to a browser
 463 nmap \b :call ExtractOpenURL('')<CR>
 464 nmap \w :call ExtractOpenURL('-n')<CR>
 465 nmap \t :call ExtractOpenURL('-t')<CR>
 466 " Send visual block to a browser
 467 vmap \b ""y:call OpenURL('<C-R>"', '')<CR>
 468 vmap \w ""y:call OpenURL('<C-R>"', '-n')<CR>
 469 vmap \t ""y:call OpenURL('<C-R>"', '-t')<CR>
 470 " Encode and send visual block to a browser
 471 vmap \B ""y:call EncodeOpenURL('<C-R>"', '')<CR>
 472 vmap \W ""y:call EncodeOpenURL('<C-R>"', '-n')<CR>
 473 vmap \T ""y:call EncodeOpenURL('<C-R>"', '-t')<CR>
 474 " Send current file's name to a browser
 475 nmap \B :call EncodeOpenURL('file:' . expand("%:p"), '')<CR>
 476 nmap \W :call EncodeOpenURL('file:' . expand("%:p"), '-n')<CR>
 477 nmap \T :call EncodeOpenURL('file:' . expand("%:p"), '-t')<CR>
 478
 479 endif " version >= 700
 480
 481
 482 " SPELLING
 483
 484 if has("spell") " Works in 7.0+
 485    " Use builtin spellchecker
 486    nmap \sv :syntax off <BAR> setlocal spell<CR>
 487    " Clear
 488    nmap \sn :syntax on <BAR> setlocal nospell<CR>
 489 endif
 490
 491
 492 " Russian letters mapped in normal mode
 493 "if has("keymap")
 494 "   set keymap=russian-jcuken
 495 "endif
 496
 497 if has("langmap")
 498    if v:version >= 702
 499       " langmap in utf-8 mode requires at least Vim 7.2.109
 500       scriptencoding utf-8
 501       set langmap=ё`Ё~йqцwуeкrеtнyгuшiщoзpх[ъ]фaыsвdаfпgрhоjлkдlж\\;э'
 502                  \яzчxсcмvиbтnьmб\\,ю.ЙQЦWУEКRЕTНYГUШIЩOЗPХ{Ъ}
 503                  \ФAЫSВDАFПGРHОJЛKДLЖ:Э\\"ЯZЧXСCМVИBТNЬMБ<Ю>
 504
 505    elseif &encoding != 'utf-8'
 506       scriptencoding koi8-r
 507       set langmap=ё`Ё~йqцwуeкrеtнyгuшiщoзpх[ъ]фaыsвdаfпgрhоjлkдlж\\;э'
 508                  \яzчxсcмvиbтnьmб\\,ю.ЙQЦWУEКRЕTНYГUШIЩOЗPХ{Ъ}
 509                  \ФAЫSВDАFПGРHОJЛKДLЖ:Э\\"ЯZЧXСCМVИBТNЬMБ<Ю>
 510    endif
 511
 512    scriptencoding us-ascii
 513 endif
 514
 515
 516 if version >= 700
 517 function! W()
 518    " let encodings=filter(split(&fileencodings, ','), 'v:val != "ucs-bom"')
 519    let encodings = ['us-ascii']
 520    if $LC_CTYPE =~ 'UTF-8' " UTF-8 or en_US.UTF-8 or ru_RU.UTF-8 or such
 521       let encodings += ['utf-8']
 522    elseif $LC_CTYPE == 'ru_RU.KOI8-R'
 523       let encodings += ['koi8-r', 'utf-8']
 524    elseif v:lc_time == 'Russian_Russia.1251'
 525       let encodings += ['cp1251', 'utf-8']
 526    endif
 527
 528    for e in encodings
 529       try
 530          execute 'set fileencoding=' . e
 531          w
 532          break
 533       catch /E513: write error, conversion failed/
 534          continue
 535       endtry
 536    endfor
 537
 538    if &modified
 539       throw '"' . expand('%') . '" E513: write error, conversion failed; tried ' . join(encodings, ',')
 540    elseif has("spell")
 541       call SetupSpell()
 542    endif
 543 endfunction
 544
 545 command! W call W()
 546 endif
 547
 548
 549 function! SlowTerm()
 550    set laststatus=1
 551    set noruler
 552    set shortmess=aoOtT
 553    set noshowcmd
 554    set scrolljump=5 " The minimal number of lines to scroll vertically when the cursor gets of the screen
 555    set sidescroll=5
 556    set nottyfast
 557    set notitle
 558    set timeoutlen=5000
 559    set nowildmenu
 560    set wildmode=list:longest
 561    set viminfo=!,h,'10,<100,s5
 562    syntax off
 563    highlight NonText cterm=NONE ctermfg=NONE
 564 endfunction
 565
 566 if exists("$SLOWTERM")
 567    call SlowTerm()
 568 endif
 569
 570
 571 if has("python")
 572 python << END_OF_PYTHON
 573 import sys, os
 574
 575 virtualenv_dir = os.environ.get('VIRTUAL_ENV')
 576 if virtualenv_dir:
 577     sys.path.insert(0, virtualenv_dir)
 578     activate_this = os.path.join(virtualenv_dir, 'bin', 'activate_this.py')
 579     execfile(activate_this, dict(__file__=activate_this))
 580 END_OF_PYTHON
 581 endif
 582
 583
 584 " From Tip 212:
 585 " http://vim.wikia.com/wiki/Setting_file_attributes_without_reloading_a_buffer
 586
 587 function! SetExecutableBit(x)
 588    if !executable('chmod')
 589       return
 590    endif
 591    checktime
 592    let fname = expand("%:p")
 593    execute "au FileChangedShell " . fname . " :echo"
 594    if a:x
 595       silent !chmod a+x %
 596    else
 597       silent !chmod a-x %
 598    endif
 599    if v:shell_error
 600       echoerr 'Error running chmod: ' . v:shell_error
 601    endif
 602    checktime
 603    execute "au! FileChangedShell " . fname
 604 endfunction
 605 command! Xbit if executable(expand("%:p")) | call SetExecutableBit(0) | else | call SetExecutableBit(1) | endif
 606
 607 " ----------
 608 " From http://slobin.pp.ru/vim/_vimrc.html
 609
 610 " These options will be kept between editing sessions
 611 " let options = []
 612
 613 " Called automagically after .viminfo and plugins are loaded, sets
 614 " miscellaneous options from persistent global variables
 615 " function! VimEnter()
 616   " for optname in g:options
 617   "   let varname = "g:OPT_" . toupper(optname)
 618   "   if exists(varname)
 619   "     execute "let &" . optname . " = " . varname
 620   "   endif
 621   " endfor
 622
 623   " if has("gui_running") && exists("g:WINPOSX") && exists("g:WINPOSY")
 624   "   execute "winpos" g:WINPOSX g:WINPOSY
 625   " endif
 626 " endfunction
 627
 628 " Called automagically before .viminfo is saved, saves miscellaneous
 629 " options into persistent global variables
 630 " function! VimLeavePre()
 631   " call filter(g:, 'v:key !~# "^OPT_"')
 632   " for optname in g:options
 633   "   let varname = "g:OPT_" . toupper(optname)
 634   "   execute "let " . varname . " = &g:" . optname
 635   " endfor
 636
 637   " if has("gui_running")
 638   "   let g:WINPOSX = getwinposx()
 639   "   let g:WINPOSY = getwinposy()
 640   " endif
 641 " endfunction
 642
 643 " autocmd VimEnter * call VimEnter()
 644 " autocmd VimLeavePre * call VimLeavePre()
 645
 646
 647 " Called automagically after every buffer read, enables fileencoding
 648 " setting from modeline (see Tip #911:
 649 " http://vim.wikia.com/wiki/How_to_make_fileencoding_work_in_the_modeline)
 650 function! AutoEncoding()
 651   if &modified && &fileencoding != ""
 652     call SetupEncoding(&fileencoding)
 653   else
 654     redraw
 655   endif
 656   autocmd! auto-encoding
 657   augroup! auto-encoding
 658 endfunction
 659
 660 augroup auto-encoding
 661 autocmd!
 662 autocmd BufWinEnter * call AutoEncoding()
 663 augroup END
 664
 665
 666 let CONVERT=1
 667
 668 " Value of a character under cursor; better than standard '0x%02B (%b)'
 669 function! HexDec()
 670   let char = matchstr(getline("."), ".", col(".") - 1)
 671   if g:CONVERT
 672     let char = iconv(char, &encoding, &fileencoding)
 673     let format = "0x%02X <%d>"
 674   else
 675     let format = "0x%02X (%d)"
 676   endif
 677   let char = char2nr(char)
 678   return printf(format, char, char)
 679 endfunction
 680
 681
 682 if has("iconv")
 683    " Helper function for :DecodeQP and :DecodeURL commands
 684    function! DecodeHex(arg)
 685      return iconv(printf("%c", str2nr(submatch(1), 16)), a:arg, &encoding)
 686    endfunction
 687
 688    " Custom completion for encoding names
 689    function! EncList(ArgLead, CmdLine, CursorPos)
 690      return filter(split(&fileencodings, ','),
 691                  \ "strpart(v:val, 0, strlen(a:ArgLead)) == a:ArgLead")
 692    endfunction
 693
 694    if version >= 700
 695    " Command for decoding qp-encoded text
 696    command! -bar -nargs=? -range -complete=customlist,EncList DecodeQP
 697           \ <line1>,<line2>s/=\(\x\x\|\n\)/\=DecodeHex(<q-args>)/eg
 698
 699    " Command for decoding url-encoded text
 700    command! -bar -nargs=? -range -complete=customlist,EncList DecodeURL
 701           \ <line1>,<line2>s/%\(\x\x\)/\=DecodeHex(<q-args>)/eg
 702    endif
 703 endif
 704
 705
 706 if has("spell")
 707    function! SetupSpell()
 708       if &fileencoding =~ 'ascii'
 709          setlocal spelllang=en spellfile=~/.vim/spell/en.ascii.add
 710       elseif &fileencoding == 'koi8-r'
 711          setlocal spelllang=en,ru spellfile=~/.vim/spell/en.ascii.add,~/.vim/spell/ru.koi8-r.add
 712       elseif &fileencoding == 'utf-8'
 713          setlocal spelllang=en,ru spellfile=~/.vim/spell/en.ascii.add,~/.vim/spell/ru.utf-8.add
 714       else
 715          setlocal spelllang= spellfile=
 716       endif
 717    endfunction
 718    autocmd BufReadPost * call SetupSpell()
 719 endif
 720
 721
 722 function! SyntaxName()
 723   echomsg synIDattr(synID(line("."), col("."), 1), "name")
 724 endfunction
 725
 726
 727 if has("python")
 728
 729 python << END_OF_PYTHON
 730
 731 import sys, rlcompleter, unicodedata, vim
 732 from itertools import *
 733 vim_complete = rlcompleter.Completer().complete
 734
 735 def vim_comp_list():
 736   """Implementation of CompList() function"""
 737   arglead = vim.eval("a:ArgLead")
 738   fence = int(vim.eval("match(a:ArgLead, '\(\w\|\.\)*$')"))
 739   left, right = arglead[:fence], arglead[fence:]
 740   try:
 741     completions = (vim_complete(right, i) for i in count())
 742     candidates = list(takewhile(bool, completions))
 743   except NameError:
 744     candidates = []
 745   suggestions = [left + x for x in candidates]
 746   vim.command("return " + repr(suggestions))
 747
 748 def vim_calc(command):
 749   """Implementation of :Calc command"""
 750   global _
 751   try:
 752     result = eval(command)
 753   except SyntaxError:
 754     exec command in globals()
 755   else:
 756     if result != None:
 757       print result
 758       _ = result
 759       xx = ''.join('\\x%02x' % ord(x) for x in str(_))
 760       vim.command('let @" = "%s"' % xx)
 761
 762 def vim_pydo(command):
 763   """Implementation of :Pydo command"""
 764   codeobj = compile(command, "command", "eval")
 765   line1 = vim.current.range.start
 766   line2 = vim.current.range.end
 767   delta = 0
 768   for numz in range(line1, line2+1):
 769     line = vim.current.buffer[numz-delta]
 770     uline = unicode(line, vim.eval('&fileencoding'))
 771     num = numz + 1
 772     words = line.split()
 773     result = eval(codeobj, globals(), locals())
 774     if result is None or result is False:
 775       del vim.current.buffer[numz-delta]
 776       delta += 1
 777       continue
 778     if isinstance(result, list) or isinstance(result, tuple):
 779       result = " ".join(map(str, result))
 780     else:
 781       result = str(result)
 782     vim.current.buffer[numz-delta] = result
 783
 784 def vim_unicode_name():
 785   try:
 786     char = vim.eval("matchstr(getline('.'), '.', col('.') - 1)")
 787     print map(unicodedata.name, char.decode(vim.eval("&encoding")))
 788   except (AttributeError, ValueError), target:
 789     print "%s: %s" % (target.__class__.__name__, target.message)
 790
 791 END_OF_PYTHON
 792
 793 " Custom completion for python expressions
 794 function! CompList(ArgLead, CmdLine, CursorPos)
 795   python vim_comp_list()
 796 endfunction
 797
 798 " Python command line calculator
 799 command! -nargs=+ -range -complete=customlist,CompList Calc
 800        \ <line1>,<line2> python vim_calc(<q-args>)
 801
 802 " Python text range filter
 803 command! -nargs=+ -range -complete=customlist,CompList Pydo
 804        \ <line1>,<line2> python vim_pydo(<q-args>)
 805
 806 " Display unicode name for the character under cursor
 807 command! Uname python vim_unicode_name()
 808 command! UName call Uname()
 809
 810 endif
 811 " ----------
 812
 813 " This has to go to the very end of ~/.vimrc to allow reading the .vimrc
 814 set secure        " safer working with script files in the current directory